如何在Stata中使用記錄的自變量生成負二項迴歸的預測計數？

我有一組數據與一個因變量是一個計數和幾個獨立變量。我的主要自變量是大美元值。如果我將美元值除以10,000（以保持係數可控制），模型（負二項和零膨脹負二項式）在Stata中運行，我可以用置信區間生成預測值。然而，從理論上講，採用這個變量的自然對數更合乎邏輯。當我這樣做時，模型仍然運行，但現在預測的計數範圍在0.22-0.77左右。我如何解決這個問題，以便預測計數正確生成？如何在Stata中使用記錄的自變量生成負二項迴歸的預測計數？

來源

2016-09-23 user6871522

您的問題不顯示任何代碼或數據。如果沒有這兩種成分，就幾乎不可能知道發生了什麼問題。你的問題是：「我爲這些其他東西做了一些令人驚訝的結果。」 爲了提出一個很好的問題，你應該使用一個數據集來複制你的編碼方法，每個人都可以訪問，比如rod93。

這是我在這個嘗試，這表明從兩個型號nbreg相當類似的預測：

webuse rod93, clear 
replace exposure = exposure/10000 

nbreg deaths exposure age_mos, nolog 
margins 
predictnl d1 =predict(n), ci(lb1 ub1) 
/* Compare the prediction for the first obs by hand */ 
di exp(_b[_cons]+_b[age_mos]*age_mos[1]+_b[exposure]*exposure[1]) 
di d1[1] 

gen ln_exp = ln(exposure) 
nbreg deaths ln_e age_mos, nolog 
margins 
predictnl d2 =predict(n), ci(lb2 ub2) 
/* Compare the prediction for the first obs by hand */ 
di exp(_b[_cons]+_b[age_mos]*age_mos[1]+_b[ln_e]*ln(exposure[1])) 
di d2[1] 
sum d? lb* ub*, sep(2)

這將產生非常類似的預測和置信區間：

. sum d? lb* ub*, sep(2) 

    Variable |  Obs  Mean Std. Dev.  Min  Max 
-------------+--------------------------------------------------------- 
      d1 |   21 84.82903 25.44322 12.95853 104.1868 
      d2 |   21  85.0432 25.24095 32.87827 105.1733 
-------------+--------------------------------------------------------- 
     lb1 |   21 64.17752 23.19418 1.895858 80.72885 
     lb2 |   21 59.80346 22.01917 10.9009 79.71531 
-------------+--------------------------------------------------------- 
     ub1 |   21 105.4805 29.39726 24.02121 152.7676 
     ub2 |   21 110.2829 29.16468 51.76427 143.856

來源

2016-09-23 22:21:52

@ user6871522這篇清楚的事情了？ –

如何在Stata中使用記錄的自變量生成負二項迴歸的預測計數？

回答

相關問題