用循環Ping腳本並保存在文本文件中

Question

我嘗試使用vbs製作Ping腳本。我需要一個腳本，每2秒鐘ping一次計算機名，並將結果保存到一個txt文件中（ping命令不會超時，程序會一直運行）。

例如：

06/08/2010 - 13:53:22 |電腦「...」在線

06/08/2010 - 13:53:24 |電腦「......」離線

現在我試着一點點：

strComputer = "TestPC" 

    Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}")._ 
    ExecQuery("select * from Win32_PingStatus where address = '"_ 
    & strComputer & "'") 
    For Each objStatus in objPing 
    If IsNull(objStatus.StatusCode) Or objStatus.StatusCode <> 0 Then 

    ..........   

    Next 

而且比我不知道如何做到這一點。 （我是新的vbs :-)）

我希望有人能幫助我。

問候， 馬蒂亞斯

Answer 1

試試這個

Option Explicit 

Dim strHost, strFile 

strHost = "www.google.com" '"127.0.0.1" 
strFile = "C:\Test.txt" 

PingForever strHost, strFile 

Sub PingForever(strHost, outputfile) 
    Dim Output, Shell, strCommand, ReturnCode 

    Set Output = CreateObject("Scripting.FileSystemObject").OpenTextFile(outputfile, 8, True) 
    Set Shell = CreateObject("wscript.shell") 
    strCommand = "ping -n 1 -w 300 " & strHost 
    While(True) 
     ReturnCode = Shell.Run(strCommand, 0, True)  
     If ReturnCode = 0 Then 
      Output.WriteLine Date() & " - " & Time & " | The Computer " & strHost & " is online" 
     Else 
      Output.WriteLine Date() & " - " & Time & " | The Computer " & strHost & " is offline" 
     End If 
     Wscript.Sleep 2000 
    Wend 
End Sub 

Answer 2

你把你的坪某種類型的循環中，然後用Wscript.Sleep 2000睡2秒。

然後您使用File System Object（FSO）寫入文件。信息可以在here找到。

編輯：這樣的事情可能工作：

Const OpenFileForAppending = 8 
Dim fso, ts 
Set fso = CreateObject("Scripting. FileSystemObject") 

While 1 > 0 ' loop forever  
    Set ts = fso.OpenTextFile("c:\temp\test.txt", OpenFileForAppending, True) 

    ' do your pinging code 

    'if ok 
     ts.WriteLine("OK") 
    'else 
     ts.WriteLine("Not OK") 
    'endif 

    ts.Close() 
    Wscript.Sleep 2000 
Wend