我可以轉換此Perl腳本以使其從文件中讀取嗎？

Question

我想使用Perl腳本來獲取特定數據列的中位數，我得到一個腳本，讀取腳本中數組的值。

my (@vals, $med); 
@vals =(12, 23, 34, 21, 66,66, 34, 87); 
print "UNSORTED: @vals\n"; #sort data points 
@vals = sort(@vals); 
print "SORTED: @vals\n"; #test to see if there are an even number of data points 
if(@vals % 2 == 0) { #if pair then: 
$sum = $vals[(@vals/2)-1] + $vals[(@vals/2)]; 
$med = $sum/2; 
print "The median value is $med\n"; 
} 
else {      #if odd then: 
print "The median value is $vals[@vals/2]\n"; 
} 
exit; 

我可以改變這個不知何故，使其從幾列的文件中讀取數據，並計算平均爲所選列？就像在shell命令中輸入./median.pl 1 column_numbers.tbl一樣。 這個我試過，但Data.txt文件只有一列

my (@vals, $med, $sum1, @numbers, @sorted); 
open (COLUMN, "< data.txt") || die "Can not open file : $! "; 
my @not_sorted = <COLUMN>;     
close (COLUMN); 
@sorted = sort { $a <=> $b } @not_sorted; 
if (@vals % 2 == 0) { 
$med = ($sorted[int($N/2)]);    
print "MEDIAN = $med\n"; 
} 
else { 
$sum1 = $vals[(@vals/2)-1] + $vals[(@vals/2)]; 
$med = $sum1/2; 
print "MEDIAN = $vals[@vals/2]\n"; 
}; 

感謝您的幫助。

Answer 1

原則上我TLP同意這一個，但因爲我發現讓有興趣的我此刻不存在其他問題：

#!/usr/bin/perl 

use strict; 
use warnings; 

my $index = shift; 
my $filename = shift; 
my $columns = []; 

open (my $fh, "<", $filename) or die "Unable to open $filename for reading\n"; 

for my $row (<$fh>) { 

    my @vals = split/\s+/, $row; 
    push @{$columns->[$_]}, $vals[$_] for 0 .. $#vals; 
} 

close $fh; 

my @column = sort {$a <=> $b} @{$columns->[$index]}; 

my $offset = int($#column/2); 
my $length = 2 - @column % 2; 

my @medians = splice(@column, $offset, $length); 

my $median; 
$median += $_ for @medians; 
$median /= @medians; 

print "$median\n"; 

這個工作，只要該數據是空格分隔。第一個參數是0索引列號，第二個參數是有效的文件名。

如果您是perl的新手，我應該注意標量上下文中的數組會返回元素的數量，如my $length = 2 - @column % 2;和$median /= @medians;。

Answer 2

你對其他專欄感興趣嗎？如果不是，則簡單地忽略它們。

該程序片段從文件讀取一行，然後將想要的列推入數組@medium_array。由於大多數人認爲第一列是第一列，但Perl認爲它是第0列，所以我添加了一個名爲COLUMN_OFFSET的偏移量。

主片的工作是通過這條線來完成：

push @medium_array, (split " ", $line)[$column_for_medium - COLUMN_OFFSET]; 

這行使用push，和split命令。不要繼續前進，直到你明白這條線是幹什麼的。

該程序可以使用一些更好的參數錯誤檢查。用戶請求的列是否大於文件中的列數？如果文件中不存在列，該怎麼辦？如果文件不存在會怎麼樣？所有這些東西都應該在這個程序中添加和檢查。

最後，這個程序將所需的列存儲到@medium_array。從那裏，你應該能夠使用你以前的代碼來找到該列的媒體。

use strict; 
use warnings; 
use autodie; 

use constant { 
    COLUMN_OFFSET => 1, #Incase you want to number cols from 1 instead of 0 
}; 

# Read in the command line parameters 

my $column_for_medium = shift; 
my $file_name   = shift; 

# Some sort of parameter checking 

if (not defined $file_name and not $column_for_medium =~ /^\d+$/) { 
    die qq(You must have two parames: "Column Num" and "File Name"); 
} 

open (my $array_file, "<", $file_name); 
my @medium_array; 
while (my $line = <$array_file>) { 
    chomp $line; 
    push @medium_array, (split " ", $line)[$column_for_medium - COLUMN_OFFSET]; 
}