Scripting.FileSystemObject在寫入方法上內存不足

Question

我正在使用此代碼將字符串寫入TXT文件。

它適用於文件< 40mbs然而，我試圖保存的TXT會有點大~45mb，並且在獲取到.write行時出現「內存不足」的錯誤。

Private Sub SaveToTXT(FilePath As String, FileContents As String) 
    Dim fso As Object 
    Dim oFile As Object 
    FileManagementFactory.DeleteIfExists (FilePath) 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set oFile = fso.CreateTextFile(FilePath) 
    Call oFile.Write(FileContents) 
    Call oFile.Close 
    Set fso = Nothing 
    Set oFile = Nothing 
End Sub 

任何想法如何繞過這個問題？

Answer 1

在這裏，試試這個。

Private Sub SaveToTXT(FilePath As String, FileContents As String) 
    Dim nFileNum As Integer: nFileNum = FreeFile 
    Open FilePath For Binary Lock Read Write As #nFileNum 
    Put #nFileNum, , FileContents 
    Close #nFileNum 
End Sub 

Answer 2

這就是我最後做的，它將文件以20,000,000個字符串分隔開。在我的測試中，它似乎超過了內存限制。

Private Sub SaveToTXT(FilePath As String, FileContents As String) 
    Dim fso As Object 
    Dim oFile As Object 
    Dim l As Long 
    Dim CharactersPerChunk As Long 
    CharactersPerChunk = 20000000 
    FileManagementFactory.DeleteIfExists (FilePath) 
    Set fso = CreateObject("Scripting.FileSystemObject") ' A lot faster than ADODB.Stream 
    Set oFile = fso.CreateTextFile(FilePath) 
    l = 0 
    While l < Len(FileContents)/CharactersPerChunk 
     Call oFile.Write(Mid(FileContents, (l * CharactersPerChunk) + 1, CharactersPerChunk)) 
     l = l + 1 
    Wend 
    Call oFile.Close 
    Set fso = Nothing 
    Set oFile = Nothing 
End Sub