刪除行如果H欄包含以下任一值 - VBA

Question

我想刪除行如果H欄包含以下任一值：

1) % 
2) Resistor 
3) Capacitor 
4) MCKT 
5) Connector 
6) anything else I may want to add to this list... 

發現這對谷歌和編輯 - 它工作得很好 - 不知道是否有更高效的方式來做到這一點。

Sub DeleteRows() 
lastrow = Cells.SpecialCells(xlCellTypeLastCell).Row 
readrow = 1 
For n = 1 to lastrow 
    If Range("H" & ReadRow).Value = "%" Or _ 
    Range("H" & ReadRow).Value = "Resistor" Or _ 
    Range("H" & ReadRow).Value = "Capacitor" Or _ 
    Range("H" & ReadRow).Value = "MCKT" Or _ 
    Range("H" & ReadRow).Value = "Connector" Then 
    Range("H" & ReadRow).EntireRow.Delete 
    Else 
     readrow = readrow + 1 
    End If 
    Next 
End Sub 

Answer 1

有更有效的方法，但是這一個：

1. 循環倒退。
2. 更改ReadRow到n，在具有兩個變量沒有任何意義：

代碼：

Sub DeleteRows() 
Dim Lastrow as long, n as long 
lastrow = Cells.SpecialCells(xlCellTypeLastCell).Row 

For n = lastrow to 1 Step -1 
    If Range("H" & n).Value = "%" Or _ 
    Range("H" & n).Value = "Resistor" Or _ 
    Range("H" & n).Value = "Capacitor" Or _ 
    Range("H" & n).Value = "MCKT" Or _ 
    Range("H" & n).Value = "Connector" Then 
     Rows(n).Delete 
    End If 
Next 
End Sub 

另一種方法是使用Select Case

Sub DeleteRows() 
Dim Lastrow as long, n as long 
lastrow = Cells.SpecialCells(xlCellTypeLastCell).Row 

For n = lastrow to 1 Step -1 

    Select Case Range("H" & n).Value 
     Case "%","Resistor","Capacitor","MCKT","Connector" 
     Rows(n).Delete 
    End Select 
Next 
End Sub 

這使得它更容易添加到名單。

Answer 2

這很好。

Option Explicit 
Option Compare Text 

Sub Delete_Rows() 

Dim LastRow As Long, ReadRow As Long, n As Long 

With ThisWorkbook.Sheets("Sheet1") 
    LastRow = .Cells(.Rows.Count, "H").End(xlUp).row 
End With 

ReadRow = 1 
For n = 1 To LastRow 
    If Range("H" & ReadRow).Value Like "*%*" = True Or _ 
    Range("H" & ReadRow).Value Like "*Resistor*" = True Or _ 
    Range("H" & ReadRow).Value Like "*Transistor*" = True Or _ 
    Range("H" & ReadRow).Value Like "*Micro*" = True Then 
     Range("H" & ReadRow).EntireRow.Delete 
    Else 
     ReadRow = ReadRow + 1 
    End If 
    Next 
End Sub