如何從特定目錄中獲取具有特定擴展名的所有文件的列表？

Question

我正在使用此代碼來獲取所有文件的特定目錄的列表：

opendir DIR, $dir or die "cannot open dir $dir: $!"; 
my @files= readdir DIR; 
closedir DIR; 

我怎麼能修改此代碼或追加的東西，以便它僅查找文本文件，只加載具有文件名前綴的數組？

實例目錄內容：

. 
.. 
923847.txt 
98398523.txt 
198.txt 
deisi.jpg 
oisoifs.gif 
lksdjl.exe 

實例數組內容：

files[0]=923847 
files[1]=98398523 
files[2]=198 

Answer 1

my @files = glob "$dir/*.txt"; 
for (0..$#files){ 
    $files[$_] =~ s/\.txt$//; 
} 

Answer 2

它是足以改變一個行：

my @files= map{s/\.[^.]+$//;$_}grep {/\.txt$/} readdir DIR; 

Answer 3

得到公正的」。 txt「文件，您可以使用文件測試操作ator（-f：常規文件）和一個正則表達式。

my @files = grep { -f && /\.txt$/ } readdir $dir; 

否則，你可以看看只是文本文件，使用Perl的-T（ASCII文本文件測試操作）

my @files = grep { -T } readdir $dir; 

Answer 4

如果你可以使用Perl 5.10的新功能，這是怎麼了我會寫它。

use strict; 
use warnings; 
use 5.10.1; 
use autodie; # don't need to check the output of opendir now 

my $dir = "."; 

{ 
    opendir my($dirhandle), $dir; 
    for(readdir $dirhandle){ # sets $_ 
    when(-d $_){ next } # skip directories 
    when(/^[.]/){ next } # skip dot-files 

    when(/(.+)[.]txt$/){ say "text file: ", $1 } 
    default{ 
     say "other file: ", $_; 
    } 
    } 
    # $dirhandle is automatically closed here 
} 

或者，如果你有非常大的目錄，你可以使用一個while循環。

{ 
    opendir my($dirhandle), $dir; 
    while(my $elem = readdir $dirhandle){ 
    given($elem){ # sets $_ 
     when(-d $_){ next } # skip directories 
     when(/^[.]/){ next } # skip dot-files 

     when(/(.+)[.]txt$/){ say "text file: ", $1 } 
     default{ 
     say "other file: ", $_; 
     } 
    } 
    } 
} 

Answer 5

只要使用此：

my @files = map {-f && s{\.txt\z}{} ? $_ :()} readdir DIR; 

Answer 6

這是我發現的最簡單的方法（如人類可讀）使用的glob功能：

# Store only TXT-files in the @files array using glob 
my @files = grep (-f ,<*.txt>); 
# Write them out 
foreach $file (@files) { 
    print "$file\n"; 
} 

此外，該「-f 「確保只有實際文件（而不是目錄）存儲在數組中。