應用XSLT記號化功能的應用模板結果

Question

我有一個正是如此格式的XML塊：

<line n="2"> 
     <orig>of right hool herte <ex>&amp;</ex> in our<ex>e</ex><note place="bottom" anchored="true" xml:id="explanatory">Although 「r」 on the painted panels of the chapel is consistently written with an otiose mark when it concludes a word, the mark here is rendered more heavily and with a dot indicating suspension above the r. This rendering as 「our<ex>e</ex>」 is a linguistic outlier for the area based on the electronic <emph rend="italic">Linguistic Atlas of Late Medieval English</emph>’s linguistic profiles for 「oure,」 「our,」 and 「our<ex>e</ex>.」 See eLALME's <ref target="http://archive.ling.ed.ac.uk/ihd/elalme_scripts/mapping/user-defined_maps.html">User Defined Maps</ref> for more information. Unfortunately the current online version (as of 12 July 2014) does not allow direct linking between static dotmaps and linguistic profiles.</note> best entent</orig> 
</line> 

我需要能夠減少它只是明文：「右HOOL herte &的以最佳範圍「，然後在空間上標記以獲得逗號或標籤分隔值的列表。我有明文通過下面的XSLT完成了位：

<xsl:template match="tei:line" > 
     <xsl:apply-templates /> 
</xsl:template> 

<xsl:template match="orig"> 
    <xsl:apply-templates/> 
</xsl:template> 

<xsl:template match="ex"> 
    <xsl:apply-templates/> 
</xsl:template> 

<xsl:template match="note"/> 

但是，我不能得到令牌化功能與應用模板的工作。如果我嘗試使用value-of，那麼標籤下面的標籤將不再正常工作。有什麼辦法可以在xml上運行apply-templates，然後在單個xslt中標記每個元素？謝謝！

Answer 1

我需要能夠減少它只是明文：在歐勒最好的「右HOOL herte &的entent「，然後在空格上標記以獲得以逗號或標記分隔值的列表的 列表。

不確定「tag-separated values」是什麼意思。鑑於以下測試輸入：

XML

<root> 
    <line n="2"> 
      <orig>of right hool herte <ex>&amp;</ex> in our<ex>e</ex><note place="bottom" anchored="true" xml:id="explanatory">Although 「r」 on the painted panels of the chapel is consistently written with an otiose mark when it concludes a word, the mark here is rendered more heavily and with a dot indicating suspension above the r. This rendering as 「our<ex>e</ex>」 is a linguistic outlier for the area based on the electronic <emph rend="italic">Linguistic Atlas of Late Medieval English</emph>’s linguistic profiles for 「oure,」 「our,」 and 「our<ex>e</ex>.」 See eLALME's <ref target="http://archive.ling.ed.ac.uk/ihd/elalme_scripts/mapping/user-defined_maps.html">User Defined Maps</ref> for more information. Unfortunately the current online version (as of 12 July 2014) does not allow direct linking between static dotmaps and linguistic profiles.</note> best entent</orig> 
    </line> 
</root> 

以下樣式：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:template match="/root"> 
    <xsl:copy> 
     <xsl:apply-templates select="line"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="line"> 
    <xsl:variable name="line-text"> 
     <xsl:apply-templates/> 
    </xsl:variable> 
    <xsl:copy> 
     <xsl:copy-of select="@n"/> 
     <xsl:value-of select="tokenize(normalize-space($line-text), ' ')" separator=", "/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="note"/> 

</xsl:stylesheet> 

將返回：

<?xml version="1.0" encoding="UTF-8"?> 
<root> 
    <line n="2">of, right, hool, herte, &amp;, in, oure, best, entent</line> 
</root> 

Answer 2

你不需要tokenize()得到這個輸出：

of right hool herte & in oure best entent 

身份與模板變換一起壓制note會爲你做它：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 

    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="note"/> 

</xsl:stylesheet> 

如果你想讓它用逗號分隔，可以將上述文本輸出捕獲到一個變量中，然後像上面提到的那樣應用tokenize：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 

    <xsl:variable name="result"> 
    <xsl:apply-templates/> 
    </xsl:variable> 

    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="note"/> 

    <xsl:template match="/"> 
    <xsl:value-of select="string-join(tokenize(normalize-space($result), ' '), ',')"/> 
    </xsl:template> 

</xsl:stylesheet> 

以上XSLT，給你的輸入XML，將產生以下文字：

of,right,hool,herte,&,in,oure,best,entent