如何查詢SQL dts包

Question

我在SQL &文件系統（.dts文件）中都有dts pacakege。我想要查詢這兩個軟件包以獲取包裹名稱，任務信息（任務名稱等）的信息。

這樣做的正確方法是什麼？

我試着執行給出dts包列表的命令。但是我不知道如何檢索其餘的信息。 EXEC msdb..sp_enum_dtspackages

阿圖爾

Answer 1

前一陣子我有同樣的問題，發現我的回答。請看看我的腳本，看看它是否有用。

dim strInputFile, strOutputFile 

for each arg in WScript.Arguments 
    select case mid(arg, 1, 3) 
     case "/i:" 
      strInputFile = mid(arg, 4) 
     case "/o:" 
      strOutputFile = mid(arg, 4) 
    end select 
next 

dim oPackage 
set oPackage = CreateObject("DTS.Package2") 
oPackage.LoadFromStorageFile strInputFile, "", "", "", "" 

dim FileSys, OutputFile 
set FileSys = CreateObject("Scripting.FileSystemObject") 
set OutputFile = FileSys.OpenTextFile (strOutputFile, 2, 1) 

dim oTasks, oProperties 
set oTasks = oPackage.Tasks 

for each oTask in oTasks 
    OutputFile.write (vbCrLf) 
    OutputFile.write (string(12 + len(oTask.Description), "-")) 
    OutputFile.write (vbCrLf) 
    OutputFile.write ("-- Task: " & oTask.Description & " --") 
    OutputFile.write (vbCrLf) 
    OutputFile.write (string(12 + len(oTask.Description), "-")) 
    OutputFile.write (vbCrLf) 

    set oProperties = oTask.Properties 

    for each oProperty in oProperties 
     OutputFile.write (oProperty.Name & " = [" & trim(oProperty.Value) & "]") 
     OutputFile.write (vbCrLf) 
    next 
next 

OutputFile.close 

set OutputFile = Nothing 
set oTasks = Nothing 
set oProperties = Nothing 
set oPackage = Nothing 
set FileSys = Nothing 

關鍵是要知道從文件系統或SQL Server加載DTS包的方法。

例如

... 
dim oPackage 
set oPackage = CreateObject("DTS.Package2") 
oPackage.LoadFromStorageFile strInputFile, "", "", "", "" 
... 

更多細節可以在MSDN上找到：
http://msdn.microsoft.com/en-us/library/aa197290%28v=sql.80%29.aspx（LoadFromSQLServer方法）
http://msdn.microsoft.com/en-us/library/aa197287%28v=sql.80%29.aspx（LoadFromStorageFile方法）