如何將整數值傳遞給其他表單？

Question

是否可以使用標籤？我計劃展示一個評分系統，就像每個正確答案一樣，評分會增加10分。

Answer 1

例如 添加兩種形式的項目 在Form2的定義Label1的控制 在Form1中

Public Class Form1 
    Private intScore As Integer = 0 
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles Me.Load 
     Form2.Show() 
    End Sub 

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click 
     Form2.Label1.Text = intScore.ToString 
    End Sub 
End Class 

Answer 2

在你的窗體2添加一個公衆共享的整數

Public Shared score As Integer = 0 

Private Sub Form2_Load(sender As Object, e As EventArgs) Handles MyBase.Load 

End Sub 

然後在Form1中通過增加它加入它

Form2.score += 50 

Answer 3

在表單中使用類的實例。表格可以調用類的方法。該類可以向表單提交事件。不要直接與班級談話。或從一個表單轉移到另一個表單

Form1中與TextBox1的：

Public Class Form1 

    Private myClass1 As Class1 
    Private myForm2 As Form2 

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load 
     myClass1 = New Class1() 
     myForm2 = New Form2(myClass1) 
     myForm2.Show() 

    End Sub 

    Private Sub TextBox1_TextChanged(sender As Object, e As EventArgs) Handles TextBox1.TextChanged 
     myClass1.SetText(TextBox1.Text) 
    End Sub 

End Class 

與窗體2的Label1：

Public Class Form2 

    Private WithEvents myClass1 As Class1 

    Public Sub New(instance As Class1) 
     InitializeComponent() 
     myClass1 = instance 
    End Sub 

    Private Sub myClass1TextSet(value As String) Handles myClass1.TextSet 
     Me.Label1.Text = value 
    End Sub 

End Class 

的Class1：

Public Class Class1 

    Private text As String = "" 

    Public Event TextSet(value As String) 

    Public Sub SetText(value As String) 
     Me.text = value 
     RaiseEvent TextSet(value) 
    End Sub 

End Class 

如您在Form1.TextBox1鍵入Form2.Label1將更新。您可以根據自己的需要更改它，但請儘量保留此結構。

表格>> >>實例類

類>> >>事件表格

的形式實例化所述另一種形式是用於本實施例的簡單性。較大規模的項目可能會有一個表單裝載機工廠負責製作表單。