您可以使用集合做到這一點:
CREATE TYPE VARCHAR2s_Table IS TABLE OF VARCHAR2(100);
/
然後輸入你的數據是這樣的:
SELECT *
FROM table_name
WHERE user_data MEMBER OF VARCHAR2s_Table('abc123','xyz456','pqr789');
或者:
您可以創建一個函數來分割數據並生成集合:
CREATE TYPE VARCHAR2_TABLE AS TABLE OF VARCHAR2(4000);
/
CREATE OR REPLACE FUNCTION split_String(
i_str IN VARCHAR2,
i_delim IN VARCHAR2 DEFAULT ','
) RETURN VARCHAR2_TABLE DETERMINISTIC
AS
p_result VARCHAR2_TABLE := VARCHAR2_TABLE();
p_start NUMBER(5) := 1;
p_end NUMBER(5);
c_len CONSTANT NUMBER(5) := LENGTH(i_str);
c_ld CONSTANT NUMBER(5) := LENGTH(i_delim);
BEGIN
IF c_len > 0 THEN
p_end := INSTR(i_str, i_delim, p_start);
WHILE p_end > 0 LOOP
p_result.EXTEND;
p_result(p_result.COUNT) := SUBSTR(i_str, p_start, p_end - p_start);
p_start := p_end + c_ld;
p_end := INSTR(i_str, i_delim, p_start);
END LOOP;
IF p_start <= c_len + 1 THEN
p_result.EXTEND;
p_result(p_result.COUNT) := SUBSTR(i_str, p_start, c_len - p_start + 1);
END IF;
END IF;
RETURN p_result;
END;
/
然後,你可以這樣做:
SELECT *
FROM table_name
WHERE user_data MEMBER OF split_String('abc123,xyz456,pqr789', ',');
或:
SELECT *
FROM table_name
WHERE user_data MEMBER OF split_String(TRIM('''' FROM '''abc123'',''xyz456'',''pqr789'''), ''',''');
來源
2016-02-26 10:46:25
MT0
的可能的複製[參數化子句的SQL](http://stackoverflow.com/questions/337704/parameterize-an-sql-in-clause) –
或這個http://stackoverflow.com/questions/6155146/problem-using-oracle-parameters-in-select-in/6155215#6155215 –
在這兩種情況下,你可以打印和發佈你的字符串'user_data'的內容,工作不工作? – Aleksej