SAS：PROC SQL作爲單個CASE的結果的多個分配

Question

我想知道是否有可能由於單個CASE而執行多個分配。也就是說，不是有兩個CASE語句，而是有一個CASE語句，它有一個'then-do-end'結構。

例如，如何根據單個CASE語句中的x將值分配給thing1和thing2？

data example; 
    input x $; 

    datalines; 
    A 
    A 
    A 
    B 
    B 
    ; 
run; 

proc sql; 
    create table make_two_from_one as 
    select * 
    , case 
     when x = 'A' then 'Result1A' 
     when x = 'B' then 'Result1B' 
     else 'Error' 
    end as thing1 
    , case 
     when x = 'A' then 'Result2A' 
     when x = 'B' then 'Result2B' 
     else 'Error' 
    end as thing2 
    from example 
    ; 
quit; 

Answer 1

Case語句構造一個變量。

爲了您的例子中，你可以試試這個，用案例的一個聲明：

data example; 
    input x $; 

    datalines; 
    A 
    A 
    A 
    B 
    B 
    ; 
run; 

proc sql; 
    create table make_two_from_one_2 as 
    select * 
    , case 
     when x = 'A' then 'Result1A,Result2A' 
     when x = 'B' then 'Result1B,Result2B' 
     else 'Error' 
    end as thing0 

    from example 
    ; 
quit; 

data example1(drop=thing0); 
    set make_two_from_one_2; 
    thing1=scan(thing0,1,','); 
    thing2=scan(thing0,2,','); 
run; 

Answer 2

在你的情況，也許你可以試試這個：

proc sql; 
    create table make_two_from_one as 
    select * 
    , case 
     when x = 'A' then 'Result1A' 
     when x = 'B' then 'Result1B' 
     else 'Error' 
    end as thing1, 
    translate(calculated thing1,'2','1') as thing2 
    from example 
    ; 
quit; 

Answer 3

我個人認爲這方面的需求，即爲了克服繁瑣的語法障礙和可以在一個地方維護的東西，對於SAS宏來說是一個很好的用例。

宏版本也避免瞭解析的危險，很好地列表，並且沒有類型假設。

%macro _case(when_A, when_B, error='Error'); 
     case 
      when x = 'A' then &when_A 
      when x = 'B' then &when_B 
      else &error 
     end 
%mend; 

proc sql; 
    create table make_two_from_one_v2 as 
    select * 
    , %_case('Result1A', 'Result1B') as thing1 
    , %_case('Result2A', 'Result2B') as thing2 
    from example 
    ; 
quit; 

Answer 4

只是爲了完整性，這是在數據步驟簡單，使用select，when，do，otherwise。或者您可以使用if,then,do,else。

data want; 
set example; 
select (x); 
    when ('A') do; 
     thing1 = 'Result1A'; 
     thing2 = 'Result2A'; 
     end; 
    when ('B') do; 
     thing1 = 'Result1B'; 
     thing2 = 'Result2B'; 
     end; 
    otherwise do; 
     thing1 = 'Error'; 
     thing2 = 'Error'; 
     end; 
end; 
run;