在Mathematica動態列表中選擇另一個動態

Question

建立在Belisarius在"Manipulate custom Tabular"提出的解決方案上。

• 考慮下面的函數來創建自定義表格表示：

  DataSampleXX[data_, linesNumber_, columnsList_, color1_, color2_, color3_] := 
  
  Grid[ 
  Join[ 
      {columnsList}, {Map[Rotate[Text[#], 90 Degree] &, 
       data[[1, columnsList]]]}, data[[2 ;; linesNumber, columnsList]]], 
  Background -> {{{{color1, color2}}, {1 -> color3}}}, 
  Dividers -> {All, {1 -> True, 2 -> True, 3 -> True, 0 -> True}}, 
  ItemSize -> {1 -> Automatic, Automatic}, 
  Alignment -> Top, 
  Frame  -> True, 
  FrameStyle -> Thickness[2], 
  ItemStyle -> {Automatic, 
  Automatic, {{1, 1}, 
  {1, Length[data]}} -> Directive[FontSize -> 15, Black, Bold]} 
  ]; 
  

• ，後面的數據：

  soData = {{"col1", "col2", "col3", "col4", "col5", "col6", "col7", 
        "col8", "col9", "col10"}, Range[1, 10], Range[11, 20], 
        Range[21, 30], Range[31, 40]} 
  
  
  With[ 
      {columnsList = {1, 3}, 
       data = soData, 
       linesNumber = 3, 
       color1 = LightBlue, 
       color2 = LightRed, 
       color3 = LightGray}, 
       DataSampleXX[data, linesNumber, columnsList, color1, color2, color3]] 
  

• 我想集成下面的Dynamic來提供DataSampleXX函數的columnsList參數。

  Manipulate[Sort@Join[Sequence @@ {a, b}], 
        Evaluate[Sequence @@ MapThread[{{#1, {}, ""}, #2, 
        ControlType -> TogglerBar} &, {{a, b}, 
        Partition[Rule @@@ Transpose[{Range[10], soData[[1]]}], 5]}]], 
        ControlPlacement -> Top] 
  

• 這將使我動態選擇列（VS一系列在我剛纔的問題列）使用DataSampleXX顯示，但我又不能老是圖瞭解如何合併這兩種機制。

Answer 1

你想做什麼需要一些技巧。

例如：

Maipulate[ f[ Array[ a, exp], ...], ...] 

和類似的構建體不工作（並且在文檔被解釋），因爲a[_]不在表達顯式的，從而使得它有一個可變數目的控制困難。我找到了解決辦法是：

Manipulate[ f[#,...], ... ] & @ Array[a, exp] 

另一個問題是構建

Control@(.#.) &/@ _controls_ 

不允許本身二維分區，所以我們必須使用這兩種控制@語法選項（控制@和{...}），這是沒有記錄。

其他令人討厭的東西你可以在下面的代碼中找到。

所以：

soData = {{"col01", "col02", "col03", "col04", "col05", "col06", 
      "col07", "col08", "col09", "col10"}, 
      Range[1, 10], Range[11, 20], Range[21, 30], Range[31, 40]}; 
perRow = 5; 
colsel = (# -> Graphics[{#, Disk[]}, ImageSize -> 15]) &/@ColorData[1, "ColorList"]; 
s[x_] := Style[x, Black, Bold, 12]; 
ct = ControlType -> PopupMenu; 

Manipulate[ 
    DataSampleXX[soData, linesNumber, Sort@Join[Sequence @@ #], color1, 
                   color2, color3], 
    Row[ 
    {Column[ 
     {Control@{{linesNumber, 2, s@"Lines"}, 
     Range[2, Length@soData[[All, 1]] - 1], ct}}], 
     Spacer[20], 
    Column[ 
     {Control@{{color1, colsel[[1, 1]], s@"Color 1"}, colsel, ct}, 
     Control@{{color2, colsel[[2, 1]], s@"Color 2"}, colsel, ct}, 
     Control@{{color3, colsel[[3, 1]], s@"Color 3"}, colsel, ct}}]}], 
    Evaluate[ 
    Sequence @@ 
    MapThread[{{#1, {}, ""}, #2, ControlType -> TogglerBar} &, 
     {#, Partition[Rule @@@ Transpose[{Range[10], soData[[1]]}], perRow]}]]] &@ 
Array[a, Length[soData[[1]]]/perRow]