SPARQL子查詢圖名

Question

我有以下包含子選擇的SPARQL查詢。該數據包含多個圖形，我想知道的進來什麼圖形爲?b和?m中的值：

select ?b, ?m, ?g1 
where { 

{ 
    select ?o1, ?o2, ?e 
    where{ 
     graph ?g{ 
     ?s <http://ndssl.bi.vt.edu/chicago/vocab/dendrogram_infector_pid> ?o1. 
     ?s <http://ndssl.bi.vt.edu/chicago/vocab/dendrogram_infectee_pid> ?o2. 
     ?s <http://ndssl.bi.vt.edu/chicago/vocab/dendrogram_iteration> '0'^^xsd:decimal. 
     ?s <http://ndssl.bi.vt.edu/chicago/vocab/dendrogram_exposureday> ?e. 
     ?s1 <http://ndssl.bi.vt.edu/chicago/vocab/contactnetwork_pid1> ?o1. 
     ?s1 <http://ndssl.bi.vt.edu/chicago/vocab/contactnetwork_pid2> ?o2. 
     ?s1 <http://ndssl.bi.vt.edu/chicago/vocab/contactnetwork_acttype1> '5'^^xsd:decimal. 
     ?s1 <http://ndssl.bi.vt.edu/chicago/vocab/contactnetwork_acttype2> '5'^^xsd:decimal 
    } 
    }ORDER BY ASC(?e) LIMIT 1 
} 

{ 

graph ?g1 { 
?b <http://ndssl.bi.vt.edu/chicago/vocab/getInfectedBy> ?o1. 
?m <http://ndssl.bi.vt.edu/chicago/vocab/getInfectedBy>* ?b. 
    } 

} 

} 

第二個圖模式包含一個傳遞屬性路徑和查詢提供了遵循正確的結果：

b              m              g1 
----------------------------------------------------- ----------------------------------------------------- ------------------------------------------------------- 
<http://ndssl.bi.vt.edu/chicago/person/pid#446734805> <http://ndssl.bi.vt.edu/chicago/person/pid#446753456> <http://ndssl.bi.vt.edu/chicago/dendrogram/replicate1/> 

但是，我想查看中間節點並計算傳遞關係的路徑長度。如果我從查詢中刪除graph ?g1，則它示出了中間節點信息等下列：

b              m 
--------------------------------------------------- --------------------------------------------------- 
http://ndssl.bi.vt.edu/chicago/person/pid#446718746 http://ndssl.bi.vt.edu/chicago/person/pid#446718746 
http://ndssl.bi.vt.edu/chicago/person/pid#446734805 http://ndssl.bi.vt.edu/chicago/person/pid#446734805 
http://ndssl.bi.vt.edu/chicago/person/pid#446734805 http://ndssl.bi.vt.edu/chicago/person/pid#446753456 

查詢的目的是要弄清楚圖形名稱匹配?b和?m。因此，我想使用graph ?g1。是否可以通過保留關鍵字來顯示中間節點？我正在使用Virtuoso。

Answer 1

由於您沒有使用g，因此不需要第一個GRAPH聲明。另請注意，第二個GRAPH語句僅使用?o1，因此以下查詢可以執行您想要的操作。您可能還想在您的select子句中檢查SPARQL syntax。

PREFIX ndssl: <http://ndssl.bi.vt.edu/chicago/vocab/> 
SELECT ?b ?m ?g1 
WHERE { 
    { 
    SELECT ?o1 
    WHERE { 
     ?s ndssl:dendrogram_infector_pid ?o1    . 
     ?s ndssl:dendrogram_infectee_pid ?o2    . 
     ?s ndssl:dendrogram_iteration  '0'^^xsd:decimal . 
     ?s ndssl:dendrogram_exposureday ?e    . 
     ?s1 ndssl:contactnetwork_pid1  ?o1    . 
     ?s1 ndssl:contactnetwork_pid2  ?o2    . 
     ?s1 ndssl:contactnetwork_acttype1 '5'^^xsd:decimal . 
     ?s1 ndssl:contactnetwork_acttype2 '5'^^xsd:decimal 
    } ORDER BY ASC(?e) LIMIT 1 
    } 
    GRAPH ?g1 { 
    ?b ndssl:getInfectedBy ?o1 . 
    ?m ndssl:getInfectedBy* ?b . 
    } 
} 

在端點提供有不匹配?b或?m，不管一個GRAPH聲明是否使用與否。