自定義着色器不能在Android上工作

Question

我將等離子球着色器從Shadertoy移植到Unity，作爲圖像效果附加到相機上。它可以在編輯器和Windows獨立版本上正常工作。它不適用於Android設備。 它在Android上閃爍藍色和黑色圖像。

下面是它看起來像在Unity編輯器和Windows編譯：

下面是它看起來像在Android上：

所移植的着色器代碼：

Shader "Hidden/Plasma Space Ball Image Effect" 
{ 
    Properties 
    { 
     iChannel0("iChannel0", 2D) = "white" {} 
    //[MaterialToggle] _isToggled("isToggle", Float) = 0 
    } 
     SubShader 
    { 
     // No culling or depth 
     Cull Off ZWrite Off ZTest Always 

     Pass 
     { 
      CGPROGRAM 
      #pragma vertex vert 
      #pragma fragment frag 

      #include "UnityCG.cginc" 

      struct appdata 
      { 
       float4 vertex : POSITION; 
       float2 uv : TEXCOORD0; 
      }; 

      struct v2f 
      { 
       float2 uv : TEXCOORD0; 
       float4 vertex : SV_POSITION; 
      }; 

      v2f vert(appdata v) 
      { 
       v2f o; 
       o.vertex = UnityObjectToClipPos(v.vertex); 
       o.uv = v.uv; 
       return o; 
      } 

      sampler2D iChannel0; 

      //Ported from https://www.shadertoy.com/view/MstXzf 

      float3 hb(float2 pos, float t, float time, float2 rot, float size, sampler2D tex0) 
      { 
       float2 newUv = 0.2*(pos/(1.2 - t) + 0.5*time*rot); 
       //float texSample = texture(tex0, newUv).b; 
       float texSample = tex2D(tex0, newUv).b; 
       float uOff = 0.2*(texSample + 0.3*time);  //lsf3RH 
       float2 starUV = newUv + float2(uOff, 0.0); 
       //return float3(0.3, 0.3, 1.0) + 1.3*texture(tex0, starUV).b; 
       return float3(0.3, 0.3, 1.0) + 1.3*tex2D(tex0, starUV).b; 
      } 

      float4 blob(float2 uv, float size, float time, sampler2D tex0) 
      { 
       float2 center = float2(0., 0.); 

       float2 pos = center - uv; 
       float t = length(pos); 
       float st = size - t; 

       float2 rot = 0.005*float2(sin(time/16.), sin(time/12.)); //MslGWN 

       float alpha = smoothstep(0.0, 0.2*size, st); 

       float3 col = hb(pos, t, time, rot, size, tex0); 
       float a1 = smoothstep(-1.4, -1.0, -col.b); 
       col = lerp(col, hb(pos, t, -time, -rot, size, tex0), a1); 

       col += 0.8*exp(-12.*abs(t - 0.8*size)/size); 
       float a2 = smoothstep(-1.4, -1.0, -col.b); 

       alpha -= a2; 

       //float crosshair = float((abs(pos.x) < 0.005 && abs(pos.y) < 0.15) || (abs(pos.y) < 0.005&&abs(pos.x) < 0.15)); 
       //return float4(col, alpha) + crosshair; 

       return float4(col, alpha); 
      } 

      float4 main_(float2 uv, float size) 
      { 
       return blob(uv, size, _Time.y, iChannel0); 
      } 


      fixed4 frag(v2f i) : SV_Target 
      { 
       float4 fragColor = 0; 
       float2 fragCoord = i.vertex.xy; 

       ///--------------------------------------------------- 

       float2 uv = fragCoord.xy/_ScreenParams.xy; 
       float2 cr = uv*2. - 1.; 
       cr.x *= _ScreenParams.x/_ScreenParams.y; 

       //late addition to elaborate background motion, could be reused later on 
       float2 rot = 0.5*float2(sin(_Time.y/16.), sin(_Time.y/12.)); 

       float4 ball = clamp(main_(cr, sin(_Time.y)*0.05 + 0.5 + 0.5), 0., 1.); 
       //float3 bg = float3(0.7, 0.7, 1.0)*texture(iChannel0, uv + rot + 0.1*ball.rb).b; 
       float3 bg = float3(0.7, 0.7, 1.0)*tex2D(iChannel0, uv + rot + 0.1*ball.rb).b; 

       //simulated gl blend 
       fragColor = float4(lerp(bg, ball.rgb, ball.a), 1.0); 
       //fragColor = lerp(fragColor,tex2D(iChannel0, i.uv).rgba,.5); 
       return fragColor; 
      } 
      ENDCG 
     } 
    } 
} 

---

您可以在上面的着色器中找到用於iChannel0輸入插槽here的圖像。

事情我已經嘗試：

• 添加着色器的圖形設置，以便統一將在構建過程中包括 它。
• 禁用Auto Graphics API並嘗試使用OpenGLES2和OpenGLES3。
• 使用Android Studio檢查日誌。完全沒有錯誤/警告。

這些都解決了這個問題，我跑出了一些東西嘗試。

軟件和設備信息是否有幫助：

• 統一4.4.2

這是用於學習和教育目的，因爲我學習GLSL 5.6.0f3

的Android，HLSL ，CG/shaderlab着色語言。我只想知道爲什麼移植的着色器在Android設備上無法按預期工作。

爲什麼它在Android上閃爍藍色和黑色圖像？

Answer 1

您需要爲OpenGLES2的片段着色器中的位置使用VPOS語義。
從Unity docs：

片段着色器能夠接收正被呈現爲 特殊VPOS語義的像素的位置。此功能只存在於着色器 模型3.0開始，因此着色器需要具有#pragma目標3.0 編譯指令。

因此，要獲得屏幕空間位置：

// note: no SV_POSITION in this struct 
struct v2f { 
    float2 uv : TEXCOORD0; 
}; 

v2f vert (
    float4 vertex : POSITION, // vertex position input 
    float2 uv : TEXCOORD0, // texture coordinate input 
    out float4 outpos : SV_POSITION // clip space position output 
    ) 
{ 
    v2f o; 
    o.uv = uv; 
    outpos = UnityObjectToClipPos(vertex); 
    return o; 
} 

fixed4 frag (v2f i, UNITY_VPOS_TYPE screenPos : VPOS) : SV_Target 
{ 
    // screenPos.xy will contain pixel integer coordinates. 
    float4 fragColor = 0; 
    float2 fragCoord = screenPos; 

但是你已經傳遞的UV所以也許你可以使用那些？

float2 uv = i.uv; 

---

事實證明我錯了。你不要在OpenGLES2片段着色器你.. 0獲得剪輯空間位置

我做了一個小測試着色器（也許有人可以解釋一下嗎？）：

CGPROGRAM 
#pragma vertex vert 
#pragma fragment frag 

float4 vert (float4 vertex : POSITION) : SV_Position 
{     
    return UnityObjectToClipPos(vertex);     
} 

fixed4 frag (float4 screenPos : SV_Position) : SV_Target 
{ 
    float uvx = screenPos.x/_ScreenParams.x; 
    return float4(uvx, 0., 0., 1.); 
} 
ENDCG 

和線float uvx = screenPos.x/_ScreenParams.x;被編譯爲
tmpvar_2.x = (0.0/_ScreenParams.x); // OpenGLES2
u_xlat0 = gl_FragCoord.x/_ScreenParams.x; // OpenGLES3

但是如果你使用的VPOS語義
fixed4 frag (float4 screenPos : VPOS) : SV_Target在同一行被編譯成
tmpvar_2.x = (gl_FragCoord.x/_ScreenParams.x); // OpenGLES2
u_xlat0 = gl_FragCoord.x/_ScreenParams.x; // OpenGLES3

所以對於OpenGLES2它看起來像你需要使用VPOS語義來獲得在片段着色器的屏幕空間位置。