在XSLT中，如何從不同範圍增加全局變量？

Question

我正在處理一個XML文件，我希望保持節點數量的計數，以便在編寫新節點時可以將它用作ID。

此刻我有一個全局變量叫做'counter'。我可以在模板中訪問它，但我還沒有找到在模板中操作它的方法。

這裏是我的XSLT文件的壓縮版：

<xsl:variable name="counter" select="1" as="xs:integer"/> 

<xsl:template match="/"> 
    <xsl:for-each select="section"> 
     <xsl:call-template name="section"></xsl:call-template> 
    </xsl:for-each> 
</xsl:template> 

<xsl:template name="section"> 

    <!-- Increment 'counter' here --> 

    <span class="title" id="title-{$counter}"><xsl:value-of select="title"/></span> 
</xsl:template> 

任何建議如何從這裏走？

Answer 1

其他人已經解釋如何變量是不可變的 - 有在XSLT沒有賦值語句（如一般而言，純函數式編程語言）。

我有迄今爲止提出的解決方案的替代方案。它避免了參數傳遞（在XSLT中冗長而醜陋 - 即使我承認這一點）。

在XPath，你可以簡單地計算它之前<section>元素的當前數量：

<xsl:template name="section"> 
    <span class="title" id="title-{1 + count(preceding-sibling::section)}"> 
    <xsl:value-of select="title"/> 
    </span> 
</xsl:template> 

（注：空格代碼格式化不會出現在你的結果，因爲只有空白文本節點因此不要強迫將指令放在同一行上）

這種方法的一大優點（與使用position()相反）是它僅依賴於當前節點，而不依賴於當前節點在當前節點列表上。如果您以某種方式更改了處理過程（例如，<xsl:for-each>不僅處理了部分，而且還處理了其他一些元素），那麼position()的值將不再需要與文檔中<section>元素的位置相對應。另一方面，如果您使用上面的count()，那麼它將始終對應於每個元素的位置。這種方法減少了與代碼的其他部分的耦合，這通常是非常好的事情。

count（）的替代方法是使用<xsl:number>指令。這是默認的行爲將在同一水平線上，這恰好是你想要的號碼的所有名稱相似的元素：

<xsl:template name="section"> 
    <xsl:variable name="count"> 
    <xsl:number/> 
    </xsl:variable> 
    <span class="title" id="title-{$count}"> 
    <xsl:value-of select="title"/> 
    </span> 
</xsl:template> 

這是一個權衡冗長（無需額外的變量聲明，如果你仍然想使用屬性值模板花括號），但只是稍微如此，因爲它也極大地簡化了XPath表達式。

還有更多的改進空間。雖然我們已經取消了對當前節點列表的依賴，但仍然依賴於當前節點。這本身並不是一件壞事，但從模板看當前節點是什麼並不明顯。我們所知道的是該模板被命名爲「section」;要確切知道正在處理的內容，我們必須查看我們的代碼中的其他地方。但即便如此，情況也不一定如此。

如果你曾經感覺到一起使用<xsl:for-each>和<xsl:call-template>（如你的例子），退後一步，並找出如何使用<xsl:apply-templates>來代替。

<xsl:template match="/doc"> 
    <xsl:apply-templates select="section"/> 
</xsl:template> 

<xsl:template match="section"> 
    <xsl:variable name="count"> 
    <xsl:number/> 
    </xsl:variable> 
    <span class="title" id="title-{$count}"> 
    <xsl:value-of select="title"/> 
    </span> 
</xsl:template> 

這不僅是方法更簡潔（<xsl:apply-templates/>取代了<xsl:for-each>和<xsl:call-template/>），但它也立即變得明確當前節點是什麼。您只需查看match屬性，即刻知道您正在處理的元素爲<section>，並且您要計算的元素爲<section>。

有關如何使用模板規則（即<xsl:template>屬性具有match屬性）的簡明說明，請參閱"How XSLT Works"。

Answer 2

變量在本地範圍內，只能在xslt中讀取。

Answer 3

XSLT變量不能更改。您將從模板傳遞值到模板。

如果您使用XSLT 2.0，則可以使用參數並使用隧道將變量傳播到正確的模板。

你的模板將是這個樣子：

<xsl:template match="a"> 
<xsl:param name="count" select="0"> 
    <xsl:apply-templates> 
    <xsl:with-param select="$count+1"/> 
    </xsl:apply-templates> 
</xsl:template> 

也期待在使用產生-ID（），如果你想創建的ID。

Answer 4

自己沒有嘗試過，但可以嘗試將參數傳遞給模板。 在您的第一個模板中，您可以在for-each語句中將參數設置爲count（）（或current（）可能？），然後將該值傳遞給您的「部分」模板。

這裏有更多關於passing parameters to templates

Answer 5

根據您的XSLT處理器，您可以引入腳本函數到您的XLST。例如，Microsoft XML庫支持包含javascript。一個例子見http://msdn.microsoft.com/en-us/library/aa970889(VS.85).aspx。如果您打算在公共客戶端瀏覽器上部署/執行XSLT，這種策略顯然不起作用;它必須由特定的XSLT處理器完成。

Answer 6

你可以使用position（）函數來做你想做的事。它看起來像這樣。

<xsl:template match="/"> 
    <xsl:for-each select="section"> 
    <xsl:call-template name="section"> 
     <xsl:with-param name="counter" select="{position()}"/> 
    </xsl:call-template> 
    </xsl:for-each> 
</xsl:template> 

<xsl:template name="section"> 
    <xsl:param name="counter"/> 
    <span class="title" id="title-{$counter}"> 
    <xsl:value-of select="title"/> 
    </span> 
</xsl:template> 

Answer 7

XSLT中的變量是不可變的，因此您必須考慮到這個問題。您既可以直接使用position()：

<xsl:template match="/"> 
    <xsl:for-each select="section"> 
     <xsl:call-template name="section"/> 
    </xsl:for-each> 
</xsl:template> 

<xsl:template name="section"> 
    <span class="title" id="title-{position()}"><xsl:value-of select="title"/></span> 
</xsl:template> 

或者在多個模板導向的方式：

<xsl:template match="/"> 
    <xsl:apply-templates select="section"/> 
</xsl:template> 

<xsl:template match="section"> 
    <span class="title" id="title-{position()}"><xsl:value-of select="title"/></span> 
</xsl:template> 

Answer 8

使用<xsl:variable name="RowNum" select="count(./preceding-sibling::*)" /> 和$ ROWNUM爲遞增值。

如：<xsl:template name="ME-homeTiles" match="Row[@Style='ME-homeTiles']" mode="itemstyle"> <xsl:variable name="RowNum" select="count(./preceding-sibling::*)" /> ...<a href="{$SafeLinkUrl}" class="tile{$RowNum}"><img ....></a>

這將爲鏈接班，值tile1，tile2，tile3等等