「在這個時候意外」發生僅單臺計算機

Question

上我們有使用下面的命令行（它是在一個批處理文件執行）一個問題：

for /f tokens^=3^ delims^=.-_^" %%j in ('cmd /c "%JAVA_HOME%\bin\java.exe" -version 2^>^&1 ^| findstr /i "version"') do set "jver=%%j" 

當我們執行這一行，我們得到java版本。這工作每次，但現在我們有與Windows 10在這裏電腦不能執行該腳本，並在這條線失敗，並說：

8 was unexpected at this time 

所以我想這個腳本能夠讀取1.8.0_101 Java版本字符串，但不知何故失敗。該jver變量僅使用一次：

if %jver% LSS 8 (
    goto :jdk_wrong_version 
) 

是否有人知道爲什麼會出現這種奇怪的行爲？因爲幾乎所有的機器都沒有這個命令的問題。我們執行java -version時的輸出似乎很好。

編輯：

以下線在啓動時運行（因此，我們檢查，如果JAVA_HOME可用）：

"%JAVA_HOME%\bin\java.exe" -version 1> NUL 2> NUL 
if not %errorLevel%==0 goto :java_not_found 

所以整個劇本是這樣的：

"%JAVA_HOME%\bin\java.exe" -version 1> NUL 2> NUL 
if not %errorLevel%==0 goto :java_not_found 

for /f tokens^=3^ delims^=.-_^" %%j in ('cmd /c "%JAVA_HOME%\bin\java.exe" -version 2^>^&1 ^| findstr /i "version"') do set "jver=%%j" 

if %jver% LSS 8 (
    goto :jdk_wrong_version 
) 

Answer 1

我懷疑"%JAVA_HOME%\bin\java.exe"不存在 - 可能JAVA_HOME尚未建立作爲環境變量。

Answer 2

我建議使用下面的批處理代碼安全檢測上確定的Java版本每一個可能的錯誤：

@echo off 
setlocal EnableExtensions DisableDelayedExpansion 
if not defined JAVA_HOME (
    echo Environment variable JAVA_HOME is not defined. 
    goto :EOF 
) 
if not exist "%JAVA_HOME%\bin\java.exe" (
    echo File "%JAVA_HOME%\bin\java.exe" does not exist. 
    goto :EOF 
) 
for /F "tokens=1-3" %%A in ('"%JAVA_HOME%\bin\java.exe" -version 2^>^&1') do (
    if /I "%%A %%B" == "java version" (
     set "JavaVersion=%%~C" 
     goto EvaluateVersion 
    ) 
) 
echo Failed to determine version of installed Java. 
goto :EOF 

:EvaluateVersion 
echo Java version is: %JavaVersion% 
for /F "tokens=2 delims=." %%I in ("%JavaVersion%") do set "jver=%%I" 
echo Main version is: %jver% 
rem More batch code. 
endlocal 

的Java打印版本來處理STDERR而不是手柄STDOUT這是什麼原因爲2>&1與由FOR執行命令行逸出運營>和&與^。

如果Java版本可以成功地確定，輸出是一樣的東西：

Java version is: 1.7.0_55 
Main version is: 7