如何在Perl或Python中只打印每三個索引？

Question

如何分別在Python和Perl中執行for（）或foreach（）循環，只打印每第三個索引？我需要將每個第三個索引移動到一個新數組中。

Answer 1

的Python

print list[::3] # print it 
newlist = list[::3] # copy it 

的Perl

for ($i = 0; $i < @list; $i += 3) { 
    print $list[$i]; # print it 
    push @y, $list[$i]; # copy it 
} 

Answer 2

的Python：

for x in a[::3]: 
    something(x) 

Answer 3

在Perl：

$size = @array; 
for ($i=0; $i<$size; $i+=3) # or start from $i=2, depends what you mean by "every third index" 
{ 
     print "$array[$i] "; 
} 

Answer 4

的Perl 5.10新state變量是非常方便的位置：

my @every_third = grep { state $n = 0; ++$n % 3 == 0 } @list; 

另外請注意，您可以提供的元素列表切片：

my @every_third = @list[ 2, 5, 8 ]; # returns 3rd, 5th & 9th items in list 

您可以動態創建使用map這片名單（見Gugod的優秀的answer）或子程序：

my @every_third = @list[ loop(start => 2, upto => $#list, by => 3 ) ]; 

sub loop { 
    my (%p) = @_; 
    my @list; 

    for (my $i = $p{start} || 0; $i <= $p{upto}; $i += $p{by}) { 
     push @list, $i; 
    } 

    return @list; 
} 

更新：

關於runrig的評論......這是 「單向」，使之成爲環內工作：

my @every_third = sub { grep { state $n = 0; ++$n % 3 == 0 } @list }->(); 

Answer 5

的Perl：

與draegtun的回答，但使用計數變量：

my $i; 
my @new = grep {not ++$i % 3} @list; 

Answer 6

 
@array = qw(1 2 3 4 5 6 7 8 9); 
print @array[(grep { ($_ + 1) % 3 == 0 } (1..$#array))]; 

Answer 7

的Perl：

# The initial array 
my @a = (1..100); 

# Copy it, every 3rd elements 
my @b = @a[ map { 3 * $_ } 0..$#a/3 ]; 

# Print it. space-delimited 
$, = " "; 
say @b; 

Answer 8

你可以在Perl做一個切片。

my @in = (1..10); 

# need only 1/3 as many indexes. 
my @index = 1..(@in/3); 

# adjust the indexes. 
$_ = 3 * $_ - 1 for @index; 
# These would also work 
# $_ *= 3, --$_ for @index; 
# --($_ *= 3) for @index 

my @out = @in[@index];