SQL查詢工作正常，但無法在動態

Question

我有一個查詢，它的工作原理，當它是這樣運行：

declare @nvRecipients varchar(4000) 
    ,@CustomerCode varchar(6) 
    ,@start datetime 
    ,@end datetime 

SELECT @CustomerCode = '10095' 
     ,@start = '01/01/2011' 
     ,@end = '02/01/2011' 

    Select substring(PSD.DTSItemCode,1,4) As ItemCompanyCode , 
    convert(varchar(50),Cast(Sum(PSD.Quantity) as money),1) As TotalShipped 
    From [AVANTISERVER\NCL_MASTER].AVANTI.dbo.PackingSlipHeader PSH 
    Inner Join [AVANTISERVER\NCL_MASTER].AVANTI.dbo.PackingSlipsDetail PSD On PSH.PKSNumber = PSD.PKSNumber 
    Where Cast (PKSDate As DateTime) >= @start 
    And Cast (PKSDate As DateTime) <= @end 
    And PSD.Quantity > 0 
    And (CompanyCode = @CustomerCode) 
    Group By substring(PSD.DTSItemCode,1,4) 
    Order By substring(PSD.DTSItemCode,1,4) 

但

語法錯誤轉換日期時間從 字符串引發錯誤。

 Set @nvQuery = ' Select substring(PSD.DTSItemCode,1,4) As ItemCompanyCode , ' 
    Set @nvQuery = @nvQuery + ' convert(varchar(50),Cast(Sum(PSD.Quantity) as money),1) As TotalShipped ' 
    Set @nvQuery = @nvQuery + ' From [AVANTISERVER\NCL_MASTER].AVANTI.dbo.PackingSlipHeader PSH ' 
    Set @nvQuery = @nvQuery + ' Inner Join [AVANTISERVER\NCL_MASTER].AVANTI.dbo.PackingSlipsDetail PSD On PSH.PKSNumber = PSD.PKSNumber ' 
    Set @nvQuery = @nvQuery + ' Where Cast (PKSDate As DateTime) >= ''' + @start + ''' ' 
    Set @nvQuery = @nvQuery + ' And Cast (PKSDate As DateTime) <= ''' + @end + ''' ' 
    Set @nvQuery = @nvQuery + ' And PSD.Quantity > 0 ' 
    Set @nvQuery = @nvQuery + ' And (CompanyCode = ''' + @CustomerCode + ''') ' 
    Set @nvQuery = @nvQuery + ' Group By substring(PSD.DTSItemCode,1,4) ' 
    Set @nvQuery = @nvQuery + ' Order By substring(PSD.DTSItemCode,1,4) ' 

有人能看到我的錯誤：

當一個存儲過程，其中@customercode，@啓動和@end被提供的參數內跑了這個樣子？我似乎無法找到它。數據全部用ISDATE（）檢出。

Answer 1

如果它們是日期，則需要將它們轉換爲varchar以附加到查詢。

不能連接日期時間爲一個字符串W/O第一投射它：

Set @nvQuery = @nvQuery + ' And Cast(PKSDate As DateTime) <= ''' + CAST(@end AS VARCHAR(20)) + ''' ' 

---

Set @nvQuery = ' Select substring(PSD.DTSItemCode,1,4) As ItemCompanyCode , ' 
    Set @nvQuery = @nvQuery + ' convert(varchar(50),Cast(Sum(PSD.Quantity) as money),1) As TotalShipped ' 
    Set @nvQuery = @nvQuery + ' From [AVANTISERVER\NCL_MASTER].AVANTI.dbo.PackingSlipHeader PSH ' 
    Set @nvQuery = @nvQuery + ' Inner Join [AVANTISERVER\NCL_MASTER].AVANTI.dbo.PackingSlipsDetail PSD On PSH.PKSNumber = PSD.PKSNumber ' 
    Set @nvQuery = @nvQuery + ' Where Cast (PKSDate As DateTime) >= ''' + CONVERT(varchar(20), @start, 101) + ''' ' 
    Set @nvQuery = @nvQuery + ' And Cast (PKSDate As DateTime) <= ''' + CONVERT(varchar(20), @end, 101) + ''' ' 
    Set @nvQuery = @nvQuery + ' And PSD.Quantity > 0 ' 
    Set @nvQuery = @nvQuery + ' And (CompanyCode = ''' + @CustomerCode + ''') ' 
    Set @nvQuery = @nvQuery + ' Group By substring(PSD.DTSItemCode,1,4) ' 
    Set @nvQuery = @nvQuery + ' Order By substring(PSD.DTSItemCode,1,4) ' 

Answer 2

要保存自己很多的麻煩，你可以使用動態SQL參數爲好，是！ - 參數，就像在真正的查詢中一樣。

Set @nvQuery = ' Select substring(PSD.DTSItemCode,1,4) As ItemCompanyCode , ' 
    Set @nvQuery = @nvQuery + ' convert(varchar(50),Cast(Sum(PSD.Quantity) as money),1) As TotalShipped ' 
    Set @nvQuery = @nvQuery + ' From [AVANTISERVER\NCL_MASTER].AVANTI.dbo.PackingSlipHeader PSH ' 
    Set @nvQuery = @nvQuery + ' Inner Join [AVANTISERVER\NCL_MASTER].AVANTI.dbo.PackingSlipsDetail PSD On PSH.PKSNumber = PSD.PKSNumber ' 
    Set @nvQuery = @nvQuery + ' Where Cast (PKSDate As DateTime) >= @start ' 
    Set @nvQuery = @nvQuery + ' And Cast (PKSDate As DateTime) <= @end ' 
    Set @nvQuery = @nvQuery + ' And PSD.Quantity > 0 ' 
    Set @nvQuery = @nvQuery + ' And (CompanyCode = @CustomerCode) ' 
    Set @nvQuery = @nvQuery + ' Group By substring(PSD.DTSItemCode,1,4) ' 
    Set @nvQuery = @nvQuery + ' Order By substring(PSD.DTSItemCode,1,4) ' 

而是通過

EXEC (@nvQuery) 

運行它的使用形式

exec sp_executeSQL @nvQuery, 
    N'@start datetime,@end datetime,@customerCode varchar(6)', --list of params 
    @start, @end, @customerCode -- params, matching list 

這周圍得到各種字符串操作，投/格式問題。例如

declare @start datetime,@end datetime,@customerCode varchar(6) 
select @start = getdate(), @end = getdate()+2, @customerCode = 'TEST' 

set @nvQuery ... -- build the statement 

exec sp_executeSQL @nvQuery, 
    N'@start datetime,@end datetime,@customerCode varchar(6)', --list of params 
    @start, @end, @customerCode -- params, matching list