我創建批處理文件將%date%轉換爲朱利安日期,但我似乎沒有找到明確的信息來執行此操作。任何人都可以告訴我如何將%date%轉換爲Julian日期?或者任何已經存在的批處理文件?將日期轉換爲朱利安日期的批處理腳本
謝謝
我創建批處理文件將%date%轉換爲朱利安日期,但我似乎沒有找到明確的信息來執行此操作。任何人都可以告訴我如何將%date%轉換爲Julian日期?或者任何已經存在的批處理文件?將日期轉換爲朱利安日期的批處理腳本
謝謝
編輯:修改後的原始代碼,只顯示Julian Day「Dow MM/DD/YYYY」格式的當前日期數量:
@echo off
for /F "tokens=2-4 delims=/ " %%a in ("%date%") do (
set /A "a=(%%a-14)/12, JDN=(1461*(%%c+4800+a))/4+(367*(%%a-2-12*a))/12-(3*((%%c+4900+a)/100))/4+%%b-32075"
)
echo %JDN%
參考:http://www.hermetic.ch/cal_stud/jdn.htm#comp
第二。編輯
要獲得序天數的基礎上,天在一年(從1到366)的數量,使用此方法:
@echo off
setlocal
for /F "tokens=2-4 delims=/ " %%a in ("%date%") do (
set /A "MM=1%%a-100, DD=1%%b-100, Ymod4=%%c%%4"
)
for /F "tokens=%MM%" %%m in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A Day=DD+%%m
if %Ymod4% equ 0 if %MM% gtr 2 set /A Day+=1
echo %Day%
隨着this這裏有一個julian.bat:
@if (@X)==(@Y) @end /* JScript comment
@echo off
cscript //E:JScript //nologo "%~f0"
exit /b %errorlevel%
@if (@X)==(@Y) @end JScript comment */
Date.prototype.getJulian = function() {
return Math.floor((this/86400000) - (this.getTimezoneOffset()/1440) + 2440587.5);
}
var today = new Date(); //set any date
var julian = today.getJulian(); //get Julian counterpart
WScript.Echo(julian);
而且它可以像使用:
for /f %%a in ('call julian.bat') do @set "julian=%%a"
我敢肯定有一個批處理文件在網絡上將日期轉換爲您想要的任何格式。 – Squashman
正如我在第一條評論中所說的。如果您搜索互聯網,您會發現已經爲您編寫的腳本! http://www.commandline.co.uk/cmdfuncs/dandt/ – Squashman
如果您將鼠標懸停在Julian日期標籤上,它會顯示:「Julian日期」這個術語也指日期數字(更合適的是**公曆日期**),特別是在計算機編程,軍事和食品行業。 – Squashman