如何使用XSLT對值進行排序？

Question

我有類似這樣的XML：

<Test> 
    <grapes> 
    <a>TypeA</a> 
    <b>value1</b> 
    </grapes> 
    <oranges> 
    <a>TypeB</a> 
    <b>value2</b> 
    </oranges> 
    <apples> 
    <a>TypeA</a> 
    <b>value3</b> 
    </apples> 
</Test> 

其中的值是唯一的，但類型，可能是相同的。

我想，這樣的輸出與此類似對它進行排序：

<group type="TypeA"> 
    <value v="value1" /> 
    <value v="value3" /> 
</group> 
<group type="TypeB"> 
    <value v="value2" /> 
</group> 

我有一個很難確保各組都在輸出獨特的價值觀是正確的小組。

我的XSL應該如何構造？

Answer 1

XSLT 1.0：

您可以通過使用muenchian方法的類型創造獨特的羣體開始。谷歌它找出它是什麼。然後，它只是一個通過他們迭代的物質和printint出你想要什麼，你想要的：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
<xsl:output method="xml" indent="yes"/> 
<xsl:key name="types" match="a" use="text()"/> 
<xsl:template match="/"> 
<result> 
    <xsl:for-each select="//a[generate-id(.) = generate-id(key('types', text())[1])]"> 
    <group type="{current()/text()}"> 
     <xsl:for-each select="//a[text() = current()/text()]"> 
     <xsl:variable name="values" select="following-sibling::b | preceding-sibling::b"/> 
     <xsl:for-each select="$values"> 
      <value v="{current()}"/> 
     </xsl:for-each> 
     </xsl:for-each> 
    </group> 
    </xsl:for-each> 
</result> 
</xsl:template> 
</xsl:stylesheet> 

你會發現，輸出等同於你所期望的。

Answer 2

我的建議是從FailedDev的略有不同：

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes" /> 

    <xsl:template match="/Test"> 
    <root> 
     <xsl:for-each select="*[a != following::a]"> 
     <xsl:sort select="a" data-type="text" /> 
     <group type="{a}"> 
      <xsl:for-each select="/Test/*[a = current()/a]"> 
      <xsl:sort select="b" data-type="text" /> 
      <value v="{b}" /> 
      </xsl:for-each> 
     </group> 
     </xsl:for-each> 
    </root> 
    </xsl:template> 
</xsl:stylesheet> 

外

<xsl:for-each select="*[a != following::a]" /> 

選擇所有獨特類型，即。 TypeA和TypeB。 的

<xsl:sort select="a" data-type="text" /> 

這些根據名稱，確保類型A上方會出現的TypeB排序。 內

<xsl:for-each select="/Test/*[a = current()/a]" /> 

選擇用於每種類型的唯一值的列表，即。對於TypeA值value1和value3被提取。再次，結果列表被排序以在值3之前列出值1。

Answer 3

這裏是一個更簡單的解決（完全 「推式」，沒有<xsl:for-each>，沒有嵌套，沒有<xsl:variable>，沒有current()，沒有//，無軸）：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:key name="kGoodsByType" match="/*/*" use="a"/> 

<xsl:template match= 
    "/*/*[generate-id() 
     = 
     generate-id(key('kGoodsByType', a)[1]) 
     ] 
    "> 
    <group type="{a}"> 
     <xsl:apply-templates select="key('kGoodsByType', a)/b"/> 
    </group> 
</xsl:template> 

<xsl:template match="b"> 
    <value v="{.}"/> 
</xsl:template> 

<xsl:template match="*/* | text()" priority="-1"/> 
</xsl:stylesheet> 

當這種轉變應用所提供的XML文檔：

<Test> 
    <grapes> 
     <a>TypeA</a> 
     <b>value1</b> 
    </grapes> 
    <oranges> 
     <a>TypeB</a> 
     <b>value2</b> 
    </oranges> 
    <apples> 
     <a>TypeA</a> 
     <b>value3</b> 
    </apples> 
</Test> 

通緝，協rrect結果產生：

<group type="TypeA"> 
    <value v="value1"/> 
    <value v="value3"/> 
</group> 
<group type="TypeB"> 
    <value v="value2"/> 
</group> 

說明：使用爲重點的a孩子的字符串值/*/*Muenchian grouping。

二， XSLT 2.0溶液：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="/*"> 
    <xsl:for-each-group select="*/a" group-by="."> 
    <group type="{current-grouping-key()}"> 
    <xsl:sequence select="current-group()/../b"/> 
    </group> 
    </xsl:for-each-group> 
</xsl:template> 
</xsl:stylesheet> 

當在同一個XML文檔（上文）中進行這種轉化，相同的正確的結果產生：

<group type="TypeA"> 
    <b>value1</b> 
    <b>value3</b> 
</group> 
<group type="TypeB"> 
    <b>value2</b> 
</group> 

說明：

1. <xsl:for-each-group>

2. current-group()

3. current-grouping-key()