如何從TextArea中獲取數據以將其保存在Winword和記事本中？

對於我的部分腳本分配，我需要創建一個html表單，該表單允許用戶將數據輸入到文本區域，然後可以將其保存爲：H驅動器中的Word或記事本文檔。使用HTA。 HTML表單部分非常簡單，但我正在努力實現它，以便點擊任一按鈕將數據保存在正確的位置。到目前爲止，我一直在努力獲得第一個按鈕來保存Word中的文件以便首先工作，但坦率地說，我不知道該從哪裏開始。這裏是我到目前爲止的代碼：如何從TextArea中獲取數據以將其保存在Winword和記事本中？

<html> 
<head> 
<HTA:APPLICATION> 

<script type="text/javascript" language="javascript"> 
function SaveFile() 
{ 
wordApp = new ActiveXObject("Word.Application"); 
wordApp.Visible = true; 
} 
</script> 
</head> 
<body> 
<form> 
Enter your information: 
<br /> 
<textarea cols="40" rows="12"> 
</textarea> 
<br /> 
<input type="button" value="save into word" id="Word.Application" /> 
<input type="button" value="save into notepad" /> 
</form> 
</body> 
</html>

我可以得到一些幫助嗎？提前致謝。

來源

2017-09-23 Paraiyar

那麼你錯過了觸發一個動作的事件。在這種情況下'onClick'。因此'onClick'會調用你的SaveFile函數。我建議有一個通用的保存函數，根據傳遞給SaveFile函數的值決定使用哪個應用程序保存數據（可以使用其中一個條件結構）。

onClick="SaveFile('notepad')" //saves data in notepad 

onClick="SaveFile('word')" //saves data in word

來源

2017-09-23 04:25:08

你可以給這個HTA一試：

<html> 
<Title>Save file into noteapd and Word Application</Title> 
<META HTTP-EQUIV="MSThemeCompatible" CONTENT="YES"> 
<head> 
<HTA:APPLICATION 
ICON="Notepad.exe" 
APPLICATIONNAME = "Save file into noteapd and Word Application" 
BORDER="dialog" 
BORDERSTYLE="complex" 
> 
</head> 
<script type="text/Vbscript"> 
'***************************************************** 
Sub window_onload() 
    CenterWindow 500,350 
End Sub 
'***************************************************** 
Sub CenterWindow(x,y) 
    Dim iLeft,itop 
    window.resizeTo x,y 
    iLeft = window.screen.availWidth/2 - x/2 
    itop = window.screen.availHeight/2 - y/2 
    window.moveTo ileft,itop 
End Sub 
'***************************************************** 
Sub Save2Word() 
'Create and Save a Word Document 
Title = "Data saved into Word Appplication" 
FileDoc = "C:\" & Month(Date) & "_" & Day(Date) & "_" & Year(Date) & ".doc" 
Set objWord = CreateObject("Word.Application") 
objWord.Visible = False 
Txtarea = document.all("Txtarea").Value 
Set objDoc = objWord.Documents.Add() 
Set objSelection = objWord.Selection 
objSelection.Font.Name = "Comic Sans MS" 
objSelection.Font.Size = "12" 
objSelection.TypeText Txtarea 
objDoc.SaveAs(FileDoc) 
objWord.Quit 
MsgBox "Data saved into : " & FileDoc,vbInformation,Title 
End Sub 
'***************************************************** 
Sub Save2Notepad() 
'Save into a Notepad Document 
Title = "Data saved into Notepad Appplication" 
Set fso = CreateObject("Scripting.FileSystemObject") 
FileTxt = "C:\" & Month(Date) & "_" & Day(Date) & "_" & Year(Date) & ".txt" 
Txtarea = document.all("Txtarea").Value 
Set oFile = fso.OpenTextFile(FileTxt,8,true) 
oFIle.WriteLine Txtarea 
oFile.Close 
MsgBox "Data saved into : " & FileTxt,vbInformation,Title 
End Sub 
'***************************************************** 
</script> 
<body> 
<center> 
<form> 
Enter your information: 
<br> 
<textarea ID="Txtarea" NAME="Txtarea" cols="40" rows="12"></textarea> 
<hr> 
<input type="button" value="save into word" onClick="Save2Word()"/> 
<input type="button" value="save into notepad" onClick="Save2Notepad()"/> 
<hr> 
</form> 
</center> 
</body> 
</html>

來源

2017-09-25 11:07:23 Hackoo

如何從TextArea中獲取數據以將其保存在Winword和記事本中？

回答

相關問題