隨機數組？

Question

在pascal中，我想隨機組織一個數組。因此，大部分時間數組應該以不同的方式組織。

考慮這個陣列設置

const 
    ARRAY_ELEMENTS = 3; 

SetLength(iIndex, ARRAY_ELEMENTS); 

for i := Low(iIndex) to High(iIndex) do 
begin 
    case i of 
    0: iIndex[i] := 0; 
    1: iIndex[i] := 1; 
    2: iIndex[i] := 2; 
    end; 
end; 

怎麼可能對於包含值0不總是在所述陣列的所述第一元件和用於包含值2 iIndex[]應不總是iIndex[]數組的最後一個值，但隨機生成數組的順序，以便初始化時數組的順序不總是相同的？

Answer 1

此代碼置換整數數組，但我不確定它是否最優（可能不是）。

type 
    TDynIntegerArray = array of integer; 

procedure PermuteArray(A: TDynIntegerArray); 
var 
    B: TDynIntegerArray; 
    Z: TDynIntegerArray; 
    π: TDynIntegerArray; 
    i: Integer; 
    j: Integer; 
    k: Integer; 
begin 
    B := Copy(A); 
    SetLength(Z, Length(A)); 
    SetLength(π, Length(A)); 
    for i := 0 to High(Z) do 
    Z[i] := i; 
    for i := 0 to High(π) do 
    begin 
    π[i] := RandomFrom(Z); 
    for j := 0 to High(Z) do 
    begin 
     if Z[j] = π[i] then 
     begin 
     for k := j to High(Z) - 1 do 
      Z[k] := Z[k+1]; 
     SetLength(Z, length(Z) - 1); 
     break; 
     end; 
    end; 
    end; 
    for i := 0 to High(A) do 
    A[i] := B[π[i]]; 
end; 

快得多，但不冷靜的做法是簡單地隨機交換項目，一對在一個時間：

procedure FastPermuteArray(A: TDynIntegerArray); 
    procedure Swap(n, m: integer); 
    var 
    tmp: integer; 
    begin 
    tmp := A[n]; 
    A[n] := A[m]; 
    A[m] := tmp; 
    end; 
var 
    i: Integer; 
begin 
    for i := High(A) downto 1 do 
    Swap(i, RandomRange(0, i)); 
end; 

Answer 2

嘗試是這樣的：

uses 
    System.Generics.Collections; 

const 
    ARRAY_ELEMENTS = 3; 
var 
    iArray: array of Integer; 
    iIndex: TList<Integer>; 
    I, j: Integer; 
begin 
    Randomize; 

    SetLength(iArray, ARRAY_ELEMENTS); 

    iIndex := TList<Integer>.Create; 
    try 
    iIndex.Count := ARRAY_ELEMENTS; 
    for i := 0 to Pred(ARRAY_ELEMENTS) do 
     iIndex[i] := i; 

    for i := Low(iArray) to High(iArray) do 
    begin 
     j := Random(iIndex.Count); 
     iArray[iIndex[j]] := i; 
     iIndex.Delete(j); 
    end; 
    finally 
    iIndex.Free; 
    end; 
end; 

如果您在您的Delphi版本中沒有TList<T>可用，您可以使用普通的TList代替：

uses 
    Classes; 

const 
    ARRAY_ELEMENTS = 3; 
var 
    iArray: array of Integer; 
    iIndex: TList; 
    I, j: Integer; 
begin 
    Randomize; 

    SetLength(iArray, ARRAY_ELEMENTS); 

    iIndex := TList.Create; 
    try 
    iIndex.Count := ARRAY_ELEMENTS; 
    for i := 0 to Pred(ARRAY_ELEMENTS) do 
     iIndex[i] := Pointer(I); 

    for i := Low(iArray) to High(iArray) do 
    begin 
     j := Random(iIndex.Count); 
     iArray[Integer(iIndex[j])] := i; 
     iIndex.Delete(j); 
    end; 
    finally 
    iIndex.Free; 
    end; 
end;