整數值轉換爲字符重複

Question

當我的XSL樣式表遇到此節點：

<node attribute="3"/> 

...它應該將它轉換成節點：

<node attribute="***"/> 

我的模板中的屬性相匹配，並重新創建它，但我不知道如何將值設置爲：字符'*'的重複次數與原始屬性的值相同。

<xsl:template match="node/@attribute"> 
    <xsl:variable name="repeat" select="."/> 
    <xsl:attribute name="attribute"> 
     <!-- What goes here? I think I can do something with $repeat... --> 
    </xsl:attribute> 
</xsl:template> 

謝謝！

Answer 1

一個相當骯髒，但務實的做法是使什麼是你指望在attribute看到的，然後使用最高的號碼的呼叫

substring("****...", 1, $repeat) 

，你在這個字符串當作有許多*小號你期望的最大數量。但我希望有更好的東西！

Answer 2

通用，遞歸解決方案（XSLT 1.0）：

<xsl:template name="RepeatString"> 
    <xsl:param name="string" select="''" /> 
    <xsl:param name="times" select="1" /> 

    <xsl:if test="number($times) &gt; 0"> 
    <xsl:value-of select="$string" /> 
    <xsl:call-template name="RepeatString"> 
     <xsl:with-param name="string" select="$string" /> 
     <xsl:with-param name="times" select="$times - 1" /> 
    </xsl:call-template> 
    </xsl:if> 
</xsl:template> 

電話爲：

<xsl:attribute name="attribute"> 
    <xsl:call-template name="RepeatString"> 
    <xsl:with-param name="string" select="'*'" /> 
    <xsl:with-param name="times" select="." /> 
    </xsl:call-template> 
</xsl:attribute> 

Answer 3

添加到@AakashM和@Tomalak，的兩個漂亮的答案，這是在XSLT自然完成2.0：

此XSLT 2.0轉換：

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="@attribute"> 
    <xsl:attribute name="{name()}"> 
    <xsl:for-each select="1 to ."> 
     <xsl:value-of select="'*'"/> 
    </xsl:for-each> 
    </xsl:attribute> 
</xsl:template> 
</xsl:stylesheet> 

時所提供的XML文檔應用：

<node attribute="3"/> 

產生想要的結果：

<node attribute="***"/> 

請注意中的XPath 2.0 to運營商是如何使用在<xsl:for-each>指令中。