蝙蝠文件刪除文件中的最後一個字符？

Question

我想弄清楚這一點，但我認爲我走了。這是我在互聯網上找到的：

copy /A data.js data.js.new /B > nul 
del data.js 
ren data.js.new data.js 

不知何故，它什麼都沒做。

如何創建一個bat文件來刪除文件中的最後一個字符（該字符是逗號，如果有的話）？

Answer 1

也許比它需要更復雜，但我想避免延遲擴展在您的文件內容中打開感嘆號，同時保留空行。批量不是這類事情的最佳語言。如果我是你，我只是使用PowerShell或JScript和substring(0, data.length - 1)或類似的。

不管怎麼說，這是一個純粹的批量解決方案：

@echo off 
setlocal 

set "file=test.txt" 
set "idx=0" 

for /f "delims=" %%I in ('findstr /n "^" "%file%"') do (
    set /a idx += 1 
    setlocal enabledelayedexpansion 
    for %%x in (!idx!) do endlocal & set "line[%%x]=%%I" 
) 

setlocal enabledelayedexpansion 
for %%I in ("!line[%idx%]!") do endlocal & set "lastline=%%~I" 
set "line[%idx%]=%lastline:~0,-1%" 

setlocal enabledelayedexpansion 
>"%file%" (
    for /L %%I in (1,1,%idx%) do echo(!line[%%I]:*:=! 
) 

這裏有一批片斷濫用PowerShell來完成相同的任務。

>out.txt powershell "$c = (gc test.txt) -join \"`n\"; $c.substring(0, $c.length - 1)" 
move /y out.txt test.txt >NUL 

或者這裏是混合批處理+ JScript解決方案。用.bat擴展名保存。

@if (@CodeSection == @Batch) @then 

@echo off & setlocal 

>out.txt (
    cscript /nologo /e:Jscript "%~f0" < test.txt 
) 

move /y out.txt test.txt >NUL 

goto :EOF 
@end // end batch/begin JScript hybrid chimera 

var data = WSH.StdIn.ReadAll(); 
WSH.StdOut.Write(data.substring(0, data.length - 1)); 

Answer 2

@echo off 
setlocal EnableDelayedExpansion 

rem Count the number of lines, minus one 
for /F %%a in ('find /C /V "" ^< data.js') do set /A lines=%%a-1 

< data.js (

    rem Copy number-1 lines 
    for /L %%i in (1,1,%lines%) do (
     set "line=" 
     set /P "line=" 
     echo(!line! 
    ) 

    rem Process last line 
    set /P "line=" 
    echo(!line:~0,-1! 

) > data.js.new 
move /Y data.js.new data.js 

Answer 3

以下批處理文件從文件中刪除​​的最後一個字符。這種方法的優點是，爲了性能，只有一個循環。它背後的想法是走路，雖然文件和輸出各一個的線條，而是通過一個迭代的延遲，因此最後一行可分別在循環後進行處理：

@echo off 
setlocal EnableExtensions DisableDelayedExpansion 
> "data.js.new" (
    for /F "delims=" %%L in (' 
     findstr /N /R "^" "data.js" 
    ') do (
     setlocal EnableDelayedExpansion 
     if defined PREV (
      set "PREV=!PREV:*:=!" 
      echo(!PREV! 
     ) 
     endlocal 
     set "PREV=%%L" 
    ) 
    setlocal EnableDelayedExpansion 
    set "PREV=!PREV:*:=!" 
    if defined PREV (
     echo(!PREV:~,-1! 
    ) 
    endlocal 
) 
endlocal 
> nul move /Y "data.js.new" "data.js" 

的for /F循環不會遍歷但通過findstr /N /R "^"的輸出，它返回所有以行號和:爲前綴的行，甚至空行也被賦予前綴，因此沒有行會顯示爲空，以便for /F，否則將忽略此行。爲了檢索循環中的原始行，除去第一個:的所有內容。

延遲環境變量擴展（由setlocal/endlocal;另請參閱set /?）已切換，腳本不會丟失任何特殊字符和/或不會崩潰。