使用xml-to-json。 「內部XML/XHTML」 應該在JSON字符串值字段

Question

我使用撒克遜家庭版，以XML轉換成JSON：

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text" encoding="UTF-8" /> 
    <xsl:template match="/"> 
     <xsl:variable name="xmljson"> 
      <map xmlns="http://www.w3.org/2005/xpath-functions"> 
       <string key="name">Some name</string> 
       <string key="description">A nice description</string> 
      </map> 
     </xsl:variable> 
     <xsl:value-of select="xml-to-json($xmljson)" /> 
    </xsl:template> 
</xsl:stylesheet> 

產生所需的輸出：

{"name":"Some name","description":"A nice description"} 

說明字段包含任意複雜的xhtml。

<string key="description">A <strong>nice</strong> description</string> 

錯誤消息：模板規則不與下面的描述領域的工作

xml-to-json: unknown element <strong> 

括在CDATA節的描述不工作：

<string key="description"><![CDATA[A <strong>nice</strong> description]]></string> 

所需的輸出：

{"name":"Some name","description":"A <strong>nice<\/strong> description"} 

問題

說明字段的內容是變換的結果。所以，隨着CDATA的失敗。 這樣可不行：

<string key="description"><xsl:apply-template select="description" /></string> 

無論是這樣的：

<string key="description"><![CDATA[<xsl:apply-template select="description" />]]></string> 

Answer 1

使用serialize() function產生逃脫的XML標記爲文本。

<xsl:variable name="options" as="element()"> 
    <output:serialization-parameters xmlns:output="http://www.w3.org/2010/xslt-xquery-serialization"> 
    <output:omit-xml-declaration value="yes"/> 
    </output:serialization-parameters> 
</xsl:variable> 

<xsl:variable name="xmljson" as="element()"> 
    <map xmlns="http://www.w3.org/2005/xpath-functions"> 
    <string key="name">Some name</string> 
    <string key="description"><xsl:value-of select="serialize(description, $options)"/></string> 
    </map> 
</xsl:variable> 

Answer 2

我想出了以下快速入門。必須再次檢查這個明天，現在有點累......牛逼

---

編輯：這是一個可怕的黑客！模板規則不處理特殊字符。請閱讀下面的評論。

---

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text" encoding="UTF-8" /> 

    <xsl:template match="/"> 
     <xsl:variable name="doc"> 
      <description>A <strong class="red">nice</strong> description</description> 
     </xsl:variable> 
     <xsl:variable name="xmljson"> 
      <map xmlns="http://www.w3.org/2005/xpath-functions"> 
       <string key="description"><xsl:apply-templates select="$doc/description/text()|$doc/description/*" /></string> 
      </map> 
     </xsl:variable> 
     <xsl:value-of select="xml-to-json($xmljson)" /> 
    </xsl:template> 

    <xsl:template match="*"> 
     <!-- opening tag --> 
     <xsl:text>&lt;</xsl:text> 
     <xsl:value-of select="name()"/> 
     <!-- attribute nodes --> 
     <xsl:apply-templates select="@*"/> 
     <xsl:text>&gt;</xsl:text> 
     <xsl:apply-templates/> 
     <!-- closing tag --> 
     <xsl:text>&lt;</xsl:text> 
     <xsl:text>/</xsl:text> 
     <xsl:value-of select="name()"/> 
     <xsl:text>&gt;</xsl:text> 
    </xsl:template> 

    <xsl:template match="@*"> 
     <xsl:text> </xsl:text> 
     <xsl:value-of select="name()"/> 
     <xsl:text>="</xsl:text> 
     <xsl:value-of select="." /> 
     <xsl:text>"</xsl:text> 
    </xsl:template> 

</xsl:stylesheet> 

產生所需的輸出：

{"description":"A <strong class=\"red\">nice<\/strong> description"}