是否可以使用XSLT樣式表過濾重複記錄？

Question

是否可以使用XSLT樣式表過濾重複記錄。我的意思是，如果你得到下面的代碼作爲輸入：

<payload> 
    <name>1</name> 
    <date>2</date> 
</payload> 
<payload> 
    <name>1</name> 
    <date>2</date> 
</payload> 
<payload> 
    <name>10</name> 
    <date>20</date> 
</payload> 
<payload> 
    <name>1</name> 
    <date>2</date> 
</payload> 

可以將其過濾輸入，產生這樣的輸出：

<payload> 
    <name>1</name> 
    <date>2</date> 
</payload> 
<payload> 
    <name>10</name> 
    <date>20</date> 
</payload> 

Answer 1

下面是一個XSLT 1.0選項...

XSLT 1.0 stylsheet

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:key name="kPayloads" match="payload" use="concat('N',name,'D',date)"/> 

    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="payloads"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*"/> 
     <xsl:apply-templates select="payload[generate-id() = generate-id(key('kPayloads', concat('N',name,'D',date)))]"/> 
    </xsl:copy> 
    </xsl:template>  

</xsl:stylesheet> 

XML輸入（合格的）

<payloads> 
    <payload> 
    <name>1</name> 
    <date>2</date> 
    </payload> 
    <payload> 
    <name>1</name> 
    <date>2</date> 
    </payload> 
    <payload> 
    <name>10</name> 
    <date>20</date> 
    </payload> 
    <payload> 
    <name>1</name> 
    <date>2</date> 
    </payload> 
</payloads> 

XML輸出

<payloads> 
    <payload> 
     <name>1</name> 
     <date>2</date> 
    </payload> 
    <payload> 
     <name>10</name> 
     <date>20</date> 
    </payload> 
</payloads> 

---

編輯

這XSLT 2.0樣式表也會產生相同的輸出...

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="payloads"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*"/> 
     <xsl:for-each-group select="payload" group-by="concat('N',name,'D',date)"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy>   
     </xsl:for-each-group> 
    </xsl:copy> 
    </xsl:template>  

</xsl:stylesheet> 

Answer 2

這是不是你想要做什麼？

<?xml version="1.0" encoding="iso-8859-1"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:cds="cds_dt" exclude-result-prefixes="cds"> 

    <xsl:template match="/"> 
     <root> 
     <xsl:apply-templates select="/root/payload"/> 
     </root> 
    </xsl:template> 

    <xsl:template match="/root/payload"> 
     <xsl:if test="not(preceding-sibling::payload/name = name)"> 
      <xsl:copy-of select="."/> 
     </xsl:if> 
    </xsl:template> 
</xsl:stylesheet>