我想編寫一個詞法生成器來將Matlab語言的基本子集轉換爲C#,C++等。爲了幫助我做到這一點,我想找到一個包含matlab形式語法的文檔。花了一些時間研究這一點,似乎數學工作不提供一個。 有誰知道我在哪裏可以找到這樣的文件?我在哪裏可以找到Matlab的正式語法?
回答
極好的機會來編寫自己的形式語法:)
如果您選擇寫語法你的自我,我可以推薦BNFC可採取正式的BNF語法和構建數據結構和詞法分析器/解析器的幾種目標語言(C/C++,C#,Java,Haskell等)。這將爲您節省大量時間,並讓您專注於制定語法,然後根據您的偏好語言正確實施轉換器。
如果沒有別的,BNFC鏈接包含一些幫助和指導如何制定一個BNF語法。祝你好運!
感謝您的建議,我會看看。我正在考慮使用fslex和fsyacc。 – 2012-03-08 15:50:03
這不是完整的語法,而是yacc-keable for matlab在2000年爲編譯器課程提供的。由此,您可以輕鬆創建BNF和EBNF。
primary_expression
: IDENTIFIER
| CONSTANT
| STRING_LITERAL
| '(' expression ')'
| '[' ']'
| '[' array_list ']'
;
postfix_expression
: primary_expression
| array_expression
| postfix_expression TRANSPOSE
| postfix_expression NCTRANSPOSE
;
index_expression
: ':'
| expression
;
index_expression_list
: index_expression
| index_expression_list ',' index_expression
;
array_expression
: IDENTIFIER '(' index_expression_list ')'
;
unary_expression
: postfix_expression
| unary_operator postfix_expression
;
unary_operator
: '+'
| '-'
| '~'
;
multiplicative_expression
: unary_expression
| multiplicative_expression '*' unary_expression
| multiplicative_expression '/' unary_expression
| multiplicative_expression '\\' unary_expression
| multiplicative_expression '^' unary_expression
| multiplicative_expression ARRAYMUL unary_expression
| multiplicative_expression ARRAYDIV unary_expression
| multiplicative_expression ARRAYRDIV unary_expression
| multiplicative_expression ARRAYPOW unary_expression
;
additive_expression
: multiplicative_expression
| additive_expression '+' multiplicative_expression
| additive_expression '-' multiplicative_expression
;
relational_expression
: additive_expression
| relational_expression '<' additive_expression
| relational_expression '>' additive_expression
| relational_expression LE_OP additive_expression
| relational_expression GE_OP additive_expression
;
equality_expression
: relational_expression
| equality_expression EQ_OP relational_expression
| equality_expression NE_OP relational_expression
;
and_expression
: equality_expression
| and_expression '&' equality_expression
;
or_expression
: and_expression
| or_expression '|' and_expression
;
expression
: or_expression
| expression ':' or_expression
;
assignment_expression
: postfix_expression '=' expression
eostmt
: ','
| ';'
| CR
;
statement
: global_statement
| clear_statement
| assignment_statement
| expression_statement
| selection_statement
| iteration_statement
| jump_statement
;
statement_list
: statement
| statement_list statement
;
identifier_list
: IDENTIFIER
| identifier_list IDENTIFIER
;
global_statement
: GLOBAL identifier_list eostmt
;
clear_statement
: CLEAR identifier_list eostmt
;
expression_statement
: eostmt
| expression eostmt
;
assignment_statement
: assignment_expression eostmt
;
array_element
: expression
| expression_statement
;
array_list
: array_element
| array_list array_element
;
selection_statement
: IF expression statement_list END eostmt
| IF expression statement_list ELSE statement_list END eostmt
| IF expression statement_list elseif_clause END eostmt
| IF expression statement_list elseif_clause
ELSE statement_list END eostmt
;
elseif_clause
: ELSEIF expression statement_list
| elseif_clause ELSEIF expression statement_list
;
iteration_statement
: WHILE expression statement_list END eostmt
| FOR IDENTIFIER '=' expression statement_list END eostmt
| FOR '(' IDENTIFIER '=' expression ')' statement_list END eostmt
;
jump_statement
: BREAK eostmt
| RETURN eostmt
;
translation_unit
: statement_list
| FUNCTION function_declare eostmt statement_list
;
func_ident_list
: IDENTIFIER
| func_ident_list ',' IDENTIFIER
;
func_return_list
: IDENTIFIER
| '[' func_ident_list ']'
;
function_declare_lhs
: IDENTIFIER
| IDENTIFIER '(' ')'
| IDENTIFIER '(' func_ident_list ')'
;
function_declare
: function_declare_lhs
| func_return_list '=' function_declare_lhs
;
Dave Wingate提供了一些看起來像一個很好的開始的Antler資源。 正如他的自述文件中指出的,他沒有包含轉置運算符和其他一些棘手的解析。見mparser鏈接在這裏:
http://web.mit.edu/~wingated/www/resources.html
一些早期版本的Matlab的(1999年)的棘手位也都在文檔中由一組來自西北描述。它包含EBNF類的描述。它還概述了一些腳註中的一些令人討厭的部分。
http://www.ece.northwestern.edu/cpdc/pjoisha/MAGICA/CPDC-TR-9909-017.pdf
我已經收集了一些其他不太相關的來源,但計算器的編輯機器人告訴我,我沒有足夠的聲譽點後兩個以上的鏈路。
您可以先調整自己用Python編寫的MATLAB - > Python轉換器smop
。它使用PLY(Python lex
- yacc
)。你可能有興趣的文件是lexer.py和parse.py。
另請參閱this answer以獲取從MATLAB到Python的轉換器列表。
- 1. 我在哪裏可以找到正式的ld鏈接器腳本語法?
- 2. 我在哪裏可以找到JSX和HTML語法參考表?
- 3. 我在哪裏可以找到的UIKit
- 4. 我在哪裏可以找到英語短語列表?
- 5. 在哪裏可以找到unattend.xml模式
- 6. 我在哪裏可以找到16F877A.h?
- 7. 我在哪裏可以找到PyBluez API
- 8. 我在哪裏可以找到Microsoft.Build.Utilities.v3.5
- 9. 我在哪裏可以找到PHPUnit_Extensions_SeleniumTestCase?
- 10. 我在哪裏可以找到compojure.html?
- 11. User.find_for_oauth - 我可以在哪裏找到它?
- 12. 我在哪裏可以找到com.mathworks.jmi包
- 13. 我在哪裏可以找到Python類?
- 14. 我在哪裏可以找到android-server.apk?
- 15. 我在哪裏可以找到org.restlet.android.jar?
- 16. 我在哪裏可以找到dict_keys類?
- 17. 我在哪裏可以找到System.Linq.Dynamic dll?
- 18. 我在哪裏可以找到InlinePageParser類?
- 19. 我在哪裏可以找到ConnectivityMonitor()?
- 20. 我在哪裏可以找到包org.omg.CosTransactions
- 21. 我在哪裏可以找到.NET v1.0.5000.0?
- 22. 我在哪裏可以找到$腳本?
- 23. 我在哪裏可以找到ExpressionParseHelper?
- 24. 我在哪裏可以找到ServerConnection類?
- 25. 我在哪裏可以找到@ Html.FacebookSignedRequest()
- 26. 我在哪裏可以找到Base64Encoder類?
- 27. 我在哪裏可以找到UAAppReviewManager-iOS.bundle
- 28. 我在哪裏可以找到Django get_absolute_url?
- 29. 我在哪裏可以找到整潔
- 30. 我在哪裏可以找到ssbdiagnose
我強烈懷疑Mathworks沒有爲Matlab定義正式的語法。我會留意這個問題的答案。 – 2012-03-06 12:02:02
Octave解析Matlab的語法。可能值得檢查他們已經做了什麼。 – 2012-03-06 14:56:16
八度音源中的[lex文件](http://hg.savannah.gnu.org/hgweb/octave/file/c1f9b54350f9/src/lex.ll)很有幫助。我還發現了一個[ant解析器](http://www.antlr.org/pipermail/antlr-interest/2011-September/042551.html),它將matlab轉換爲C和Java。 – 2012-03-09 09:00:36