取消引用散列元素中的列表引用

Question

有人能爲我完成此操作並解釋你做了什麼嗎？

my %hash; 

#$hash{list_ref}=[1,2,3]; 
#my @array=@{$hash{list_ref}}; 

$hash{list_ref}=\[1,2,3]; 
my @array=??? 

print "Two is $array[1]"; 

Answer 1

my %hash; 

#$hash{list_ref}=[1,2,3]; 

#Putting the list in square brackets makes it a reference so you don't need '\' 
$hash{list_ref}=[1,2,3]; 

#If you want to use a '\' to make a reference it is done like this: 
# $something = \(1,2,3); # A reference to a list 
# 
# or (as I did above)... 
# 
# $something = [1,2,3]; # Returns a list reference 
# 
# They are the same (for all intent and purpose) 


print "Two is $hash{list_ref}->[1]\n"; 


# To make it completely referenced do this: 
# 
# $hash = {}; 
# $hash->{list_ref} = [1,2,3]; 
# 
# print $hash->{list_ref}[1] . "\n"; 

要獲取數組（數組或列表）做到這一點：

my @array = @{ $hash{list_ref} } 

Answer 2

@array = @{${$hash{list_ref}}}; 

(1,2,3)是一個列表。

[1,2,3]是 參考列表 的陣列（技術上，有在Perl沒有這樣的東西，以列表的引用）。

\[1,2,3]是對數組引用的引用。

$hash{list_ref}是對數組引用的引用。

${$hash{list_ref}}是對數組的引用。

@{${$hash{list_ref}}}是一個數組。

由於引用被認爲是標量，因此對引用的引用是標量引用，並且在中間步驟中使用標量解引用操作符${...}。

Answer 3

[ EXPR ] 

創建一個匿名數組，將由EXPR返回的值賦給它，並返回對它的引用。這意味着它幾乎一樣

do { my @anon = (EXPR); \@anon } 

這意味着，

\[ EXPR ] 

幾乎是一樣的

do { my @anon = (EXPR); \\@anon } 

這不是一個正常看到。

---

換句話說，

1,2,3返回三個元素（在列表上下文）的列表。

(1,2,3)與以前相同。 Parens隻影響優先級。

[1,2,3]返回對包含三個元素的數組的引用。

\[1,2,3]返回對包含三個元素的數組的引用的引用。

---

在實踐中：

my @data = (1,2,3); 
print @data; 

my $data = [1,2,3];  $hash{list_ref} = [1,2,3]; 
print @{ $data };  print @{ $hash{list_ref} }; 

my $data = \[1,2,3];  $hash{list_ref} = \[1,2,3]; 
print @{ ${ $data } }; print @{ ${ $hash{list_ref} } }; 

Answer 4

其他人幾乎已經回答了這個問題，但更普遍，如果您對數據結構感到困惑，請使用Data::Dumper。這將打印出神祕的數據結構，並幫助您解析它。

use strict;  #Always, always, always 
use warnings; #Always, always, always 
use feature qw(say); #Nicer than 'print' 

use Data::Dumper;  #Calling in the big guns! 

my $data_something = \[1,2,3]; 

say Dumper $data_something; 
say Dumper ${ $data_something }; 

讓我們來看看它打印出...

$ test.pl 

$VAR1 = \[ 
      1, 
      2, 
      3 
      ]; 

$VAR1 = [ 
      1, 
      2, 
      3 
     ]; 

從第一場，看來$data_something是一個普通的標引用數組引用。這讓我在第一次運行該程序後添加第二個Dumper。這表明${ $data_something }現在是對數組的引用。

我現在可以訪問陣列像這樣：

use strict;  #Always, always, always 
use warnings; #Always, always, always 
use feature qw(say); #Nicer than 'print' 

use Data::Dumper;  #Calling in the big guns! 

my $data_something = \[1,2,3]; 

# Double dereference 
my @array = @{ ${ $data_something } }; #Could be written as @$$data_something 

for my $element (@array) { 
    say "Element is $element"; 
} 

而現在......

$ test.pl 
Element is 1 
Element is 2 
Element is 3 

它看起來像你的意思是：

my $hash{list_ref} = [1,2,3]; 

，而不是：

$hash{list_ref} = \[1,2,3]; 

後者給了你一個數組引用的標量引用，除了給這種情況添加混淆之外，真的不會對你有所幫助。

然後，你所要做的只是指一個特定的元素是$hash{list_ref}->[0]。這只是${ $hash{list_ref} }[0]的快捷方式。閱讀和理解起來更容易。

use strict; 
use warnings; 
use feature qw(say); 

my %hash; 
$hash{list_ref} = [1, 2, 3]; 

foreach my $element (0..2) { 
    say "Element is " . $hash{list_ref}->[$element]; 
} 

而且......

$ test.pl 
Element is 1 
Element is 2 
Element is 3 

所以，下一次你無所適從一個特定的數據結構看起來像（和它發生在我們最好的。嗯......不是我們最好的，它發生在我身上），使用Data::Dumper。