用XSLT轉換GML

Question

我想弄清楚這段代碼有什麼問題，但是4小時後我放棄了！我在這裏嘗試了很多不同的解決方案，從web，bot都無法工作。

我想要做的是將「gml：coordinates」值放到「point」屬性中。我想這與名字空間有關。還是其他什麼東西......

XML文件：

<?xml version="1.0" encoding="ISO-8859-1"?> 
<gml:LineString> 
    <gml:coordinates>-7 -7 0 7 -7 0 7 7 0 -7 7 0</gml:coordinates> 
</gml:LineString> 

XSL文件：

<?xml version="1.0" encoding="ISO-8859-1"?> 
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:gml="http://www.opengis.net/gml"> 

<xsl:template match="/gml:LineString"> 
    <Transform> 
     <Shape> 
      <IndexedFaceSet> 
       <xsl:attribute name="coordIndex"> 
        <xsl:text>0 1 2 3 -1</xsl:text> 
       </xsl:attribute> 

       <Coordinate> 
        <xsl:attribute name="point"> 
         <xsl:text> 
          <xsl:value-of select="/gml:coordinates" /> 
         </xsl:text> 
        </xsl:attribute> 
       </Coordinate> 
      </IndexedFaceSet> 
     </Shape> 
    </Transform> 
</xsl:template> 
</xsl:stylesheet> 

而阿賈克斯腳本（返回正確的結果，如果屬性被設置爲「-7 -7 0 7 -7 0 7 7 0 -7 7 0「insted of」/ gml：coordinates「）：

var xml = document.implementation.createDocument("", "", null); 
var xsl = document.implementation.createDocument("", "", null); 
xml.async = false; 
xsl.async = false; 
xml.load("xsl/ajax.xml"); 
xsl.load("xsl/ajax.xsl"); 
var processor = new XSLTProcessor(); 
processor.importStylesheet(xsl); 
var output = processor.transformToFragment(xml, document); 
document.getElementById("scene").appendChild(output); 

在此先感謝。

Answer 1

只需更換：

<Coordinate> 
    <xsl:attribute name="point"> 
    <xsl:text> 
     <xsl:value-of select="/gml:coordinates" /> 
    </xsl:text> 
    </xsl:attribute> 
</Coordinate> 

與：

<Coordinate> 
    <xsl:attribute name="point"> 
     <xsl:value-of select="gml:coordinates" /> 
    </xsl:attribute> 
</Coordinate> 

說明：至少有兩個問題在這裏：

1. <xsl:text>不能在其內部包含其他xsl元素 - 只有文本。

2. XPath表達式/gml:coordinates未選擇任何內容，因爲源XML文檔中沒有/gml:coordinates top元素。

此外重構：該代碼可以通過使用*來進一步簡化AVT * S（屬性 - 值模板）：

替換：

<Coordinate> 
    <xsl:attribute name="point"> 
     <xsl:value-of select="gml:coordinates" /> 
    </xsl:attribute> 
</Coordinate> 

與：

<Coordinate point="{gml:coordinates}"/> 

更換：

<IndexedFaceSet> 
    <xsl:attribute name="coordIndex"> 
    <xsl:text>0 1 2 3 -1</xsl:text> 
    </xsl:attribute> 

與：

<IndexedFaceSet coordIndex="0 1 2 3 -1"> 

完整代碼的修正和重構後：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:gml="http://www.opengis.net/gml"> 
    <xsl:template match="/gml:LineString"> 
     <Transform> 
      <Shape> 
       <IndexedFaceSet coordIndex="0 1 2 3 -1"> 
        <Coordinate point="{gml:coordinates}"/> 
       </IndexedFaceSet> 
      </Shape> 
     </Transform> 
    </xsl:template> 
</xsl:stylesheet> 

，其結果是：

<Transform xmlns:gml="http://www.opengis.net/gml"> 
    <Shape> 
     <IndexedFaceSet coordIndex="0 1 2 3 -1"> 
      <Coordinate point="-7 -7 0 7 -7 0 7 7 0 -7 7 0"/> 
     </IndexedFaceSet> 
    </Shape> 
</Transform>