將問題打印到新文件中的Perl問題

Question

我想刪除以HPL_開頭的文本文件中的所有行我已經完成了此操作並可以打印到屏幕上，但是當我嘗試寫入文件時，新文件中打印的修改文本的一行。請任何幫助！

open(FILE,"<myfile.txt"); 
@LINES = <FILE>; 
close(FILE); 
open(FILE,">myfile.txt"); 
foreach $LINE (@LINES) { 
@array = split(/\:/,$LINE); 


my $file = "changed"; 

open OUTFILE, ">$file" or die "unable to open $file $!"; 

print OUTFILE $LINE unless ($array[0] eq "HPL_"); 

} 
close(FILE); 
close (OUTFILE); 




exit; 

Answer 1

你只是想刪除所有以HPL_開頭的行嗎？這很容易！

perl -pi -e 's/^HPL_.*//s' myfile.txt 

是的，它真的只是一個班輪。 :-)

Answer 2

如果你不想使用一個內膽，重新寫了「寫入文件」部分如下：

my $file = "changed"; 
open(my $outfh, '>', $file) or die "Could not open file $file: $!\n"; 
foreach my $LINE (@LINES) { 
    my @array = split(/:/,$LINE); 
    next if $array[0] eq 'HPL_'; 
    print $outfh $LINE; 
} 
close($outfh); 

注意你是如何open()每次荷蘭國際集團的文件通過循環。這導致文件只包含最後一行，因爲使用open()而>表示「覆蓋文件中的內容」。這是你代碼的主要問題。

編輯：另一方面，你想清理你的代碼。正如我所示，使用詞法文件句柄。總是添加tchrist發佈在每個Perl程序頂部的三行代碼。使用三運營商版本open()。不要將整個文件寫入數組，因爲如果您嘗試讀取大文件，可能會導致計算機內存不足。您的程序可以被重新寫爲：

#!perl 

use strict; 
use autodie; 
use warnings FATAL => "all"; 

my $infile = "myfile.txt"; 
my $outfile = "changed.txt"; 

open(my $infh, '<', $infile); 
open(my $outfh, '>', $outfile); 
while(my $line = <$infh>) { 
    next if $line =~ /^HPL_/; 
    print $outfh $line; 
} 
close($outfh); 
close($infh); 

注意你不需要添加or die ...到open()功能如何與use autodie，作爲autodie編譯處理，對你。

Answer 3

您的代碼問題在於，您在行處理循環中打開了用於輸出的文件，由於您使用open的「>」形式，每次打開文件時都會打開文件，刪除以前的任何內容。

將open（）的調用移動到文件頂部，在循環上方，它應該可以工作。

此外，我不確定你的意圖，但在你的例子的第4行，你重新打開你的輸入文件進行寫入（使用'>'），這也會破壞它包含的任何東西。

作爲一個側面說明，你可以嘗試在Perl的grep的（）命令，其目的是做的正是你所需要的，閱讀起來如：

#!/usr/bin/perl 
use strict; 
use warnings; 

open(my $in, '<', 'myfile.txt') or die "failed to open input for read: $!"; 
my @lines = <$in> or die 'no lines to read from input'; 
close($in); 

# collect all lines that do not begin with HPL_ into @result 
my @result = grep ! /^HPL_/, @lines; 

open(my $out, '>', 'changed.txt') or die "failed to open output for write: $!"; 
print { $out } @result; 
close($out);