合併到和SCOPE_IDENTITY問題

Question

我使用SQL Server 2008和merge into從表值參數得到我的數據。

CREATE PROCEDURE [dbo].[SP1] 
    (
    @p as TTVP readonly  
    ) 

AS 
declare @ThisId int 
Begin 

    Merge into [dbo].[FIRSTTABLE] tp 
    Using @p ps 
    on tp.ID = ps.ID 

    When Matched Then 
    Update 
    set tp.NAME = ps.NAME, 
    tp.myDATE = Getdate() 

    When Not Matched Then 

    insert (NAME, myDATE) 
    Values (ps.NAME, getDate()); 

    seclect @ThisId = identity_scope() 

    insert into SECONDTABLE (ID, myDATE) 
    select (@ThisId, Getdate()) 

    END 

我覺得我從來沒有scope_identity從我insert語句獲取的ID。

所以我的第一個更新和插入的作品，但我如何得到我的第二個插入插入的ID？

Answer 1

這表明如何從MERGE語句記錄輸出數據。請注意，OUTPUT子句在MERGE中的所有分支上運行，包括UPDATE和INSERT部分。然後使用inserted.id和deleted.id之間的不匹配來確定實際插入的內容。 OUTPUT子句展示瞭如何發揚從inserted虛擬表name列。

use tempdb; 

-- create the test tables and table type 
create table dbo.FirstTable (
    ID int identity primary key, 
    NAME sysname, 
    myDATE datetime); 
GO 
create table dbo.SecondTable (
    ID int primary key, 
    myDATE datetime, 
    NAME sysname); 
GO 
create type TTVP as TABLE(ID int, NAME sysname); 
GO 

-- create the procedure 
CREATE PROCEDURE dbo.SP1 
    @p as TTVP readonly 
AS 
SET NOCOUNT ON; 

create table #cache (new_id int primary key, old_id int, name sysname); 

merge into dbo.firsttable tp 
using @p ps on tp.id = ps.id 
when matched then 
    update 
     set tp.name = ps.name, 
      tp.mydate = getdate() 
when not matched then 
    insert (name, mydate) 
    values (ps.name, getdate()) 
output inserted.id, deleted.id, inserted.name into #cache; 

insert into dbo.secondtable (id, mydate, name) 
select new_id, getdate(), name 
from #cache 
where old_id is null; 
GO 

-- set up some test data (2 rows) 
truncate table dbo.FirstTable; 
insert dbo.FirstTable values ('abc', getdate()); 
insert dbo.FirstTable values ('ghi', getdate()-1); 
GO 

-- execute the procedure 
declare @p TTVP; 
insert @p values (1, 'abc'),(2, 'xyz'),(3, 'def'); 
exec dbo.SP1 @p; 

-- check the results 
select * from dbo.firsttable 
select * from dbo.secondtable