vba在打開時顯示用戶窗體，隱藏工作表，但保留任務欄圖標

Question

我有一個用戶窗體在打開工作簿時打開。 Excel也是隱藏的，這樣用戶窗體就會顯示給用戶。

Private Sub Workbook_Open() 
Application.Visible = False 
UserForm1.Show vbModeless 
End Sub 

然而，這也隱藏了Excel的圖標在任務欄上，這樣當用戶從用戶窗體中點擊了他們不能回，除非使用Alt + Tab或關閉/最小化其他窗口是在前面的用戶表單。我不希望用戶這樣做，有些甚至可能會嘗試再次打開表單（假定它已關閉），導致重新打開的提示和錯誤，我也不想這樣做。

本質上，我需要用戶窗體的任務欄上的圖標。

一旦用戶窗體關閉我有它，以便Excel關閉

Unload UserForm1 
Application.Quit 

例子我已經在網上對於這個問題上找到不太達到什麼，我試圖做的。 改變形式，以儘量減少和開放的模式工作，以保持圖標在任務欄，而不是讓用戶編輯工作表

Application.WindowState = xlMinimized 
UserForm1.Show (1) 

但是，這裏有2個問題.....月1日 - 用戶窗體不成爲焦點，第二 - 用戶可以點擊任務欄圖標，工作表現在可以在用戶窗體後面看到，這不是我能夠做到的。

Answer 1

發表加雷思關於這個問題的答案：

Excel Useform: How to hide application but have icon in the taskbar

合作，給我一個任務欄圖標，是一個簡單的複製和粘貼。

謝謝大家的幫助。

Answer 2

而不是隱藏應用程序最小化工作簿：

ThisWorkbook.Windows(1).WindowState = xlMinimized 

Answer 3

我花的時間量在Excel-的Visio應用程序的開發這一任務，並面臨着同樣的問題（Excel表格以上的Visio/Excel和VBA編輯器是隱藏的 - 但用戶很容易失去焦點，只能退回 - Alt-Tabbing）。同樣的問題！

我的算法來解決這個問題是這樣的（在用戶窗體類中的所有代碼）：

Private Sub UserForm_Initialize() 

    'some init's above 
    ToggleExcel   'Toggle excel, all windows are hidden now! 
    ActivateVisio  'Visio fired and on top 
    SetStandAloneForm 'Let's customize form 
End Sub 

所以在啓動時，我們有我們所期望的Visio和形式。再次在Terminate事件I ToggleExcel並儘量減少Visio。

ToggleExcel：

Private Function ToggleExcel() 
    Static IsVBEWasVisible As Boolean 

    With Application 
     If .Visible = True Then 
      IsVBEWasVisible = .VBE.MainWindow.Visible 
      If IsVBEWasVisible Then _ 
        .VBE.MainWindow.Visible = False 
      .WindowState = xlMinimized 
      .Visible = False 
     Else 
      If IsVBEWasVisible Then _ 
        .VBE.MainWindow.Visible = True 
      .WindowState = xlMaximized 
      .Visible = True 
     End If 
    End With 
End Function 

SetStandAloneForm：

要SetStandAloneForm我聲明API函數的塊：

#If VBA7 Then 
    Private Declare PtrSafe Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long 
    Private Declare PtrSafe Function ShowWindow Lib "user32" (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long 
    Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long 
    Private Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long 
    Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hWnd As Long) As Long 
#Else 
    Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long 
    Private Declare Function ShowWindow Lib "user32" (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long 
    Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long 
    Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long 
    Private Declare Function SetFocus Lib "user32" (ByVal hWnd As Long) As Long 
#End If 

實際SetStandAloneForm：

Private Function SetStandAloneForm() 
    Const GWL_STYLE As Long = -16 
    Const GWL_EXSTYLE As Long = -20 
    Const WS_CAPTION As Long = &HC00000 
    Const WS_MINIMIZEBOX As Long = &H20000 
    Const WS_MAXIMIZEBOX As Long = &H10000 
    Const WS_POPUP As Long = &H80000000 
    Const WS_VISIBLE As Long = &H10000000 
    Const WS_EX_DLGMODALFRAME As Long = &H1 
    Const WS_EX_APPWINDOW As Long = &H40000 
    Const SW_SHOW As Long = 5 

    Dim Hwnd As Long 
    Dim CurrentStyle As Long 
    Dim NewStyle As Long 

    If Val(Application.Version) < 9 Then 
     Hwnd = FindWindow("ThunderXFrame", Me.Caption) 'XL97 
    Else 
     Hwnd = FindWindow("ThunderDFrame", Me.Caption) '>XL97 
    End If 

    'Let's give to userform minimise and maximise buttons 
    CurrentStyle = GetWindowLong(Hwnd, GWL_STYLE) 
    NewStyle = CurrentStyle Or WS_MINIMIZEBOX Or WS_MAXIMIZEBOX 
    NewStyle = NewStyle And Not WS_VISIBLE And Not WS_POPUP 
    Call SetWindowLong(Hwnd, GWL_STYLE, NewStyle) 

    'Let's give to userform a taskbar icon 
    CurrentStyle = GetWindowLong(Hwnd, GWL_EXSTYLE) 
    NewStyle = CurrentStyle Or WS_EX_APPWINDOW 
    Call SetWindowLong(Hwnd, GWL_EXSTYLE, NewStyle) 
    Call ShowWindow(Hwnd, SW_SHOW) 

End Function