只用相對路徑或文件名刪除或替換EAssertionFailed的絕對路徑？

Question

是否有某種方法可以刪除或替換EAssertionFailed錯誤消息的絕對路徑？我想不包括整個路徑，不要間接泄露源代碼的編譯位置，並使消息獨立於該位置。優選地，只有項目根目錄或DPR文件的相對路徑或源文件名纔會包含在錯誤消息中。

---

程序輸出：

EAssertionFailed: Assertion failed (C:\Users\User\Documents\ 
Embarcadero\Studio\Projects\Project3.dpr, line 12) 

Project3.dpr

program Project3; 

{$AppType Console} 

{$R *.res} 

uses 
    System.SysUtils; 

begin 
    try 
    Assert(False); 
    except 
    on E: Exception do 
    begin 
     WriteLn(E.ClassName, ': ', E.Message); 
     ReadLn; 
    end; 
    end; 
end. 

Answer 1

更換或鉤AssertErrorProc和改變或抑制文件名和行號的信息。

program Project1; 

{$APPTYPE CONSOLE} 

{$R *.res} 

uses 
    System.SysConst, 
    System.SysUtils; 

    procedure CustomAssertErrorHandler(const Message, Filename: string; LineNumber: Integer; ErrorAddr: Pointer); 

    var 
     FileNameOnly : string; 

    begin 
     FileNameOnly := ExtractFileName(FileName); 

     if Message <> '' then 
     raise EAssertionFailed.CreateFmt(SAssertError, 
      [Message, FileNameOnly, LineNumber]) at ErrorAddr 
     else 
     raise EAssertionFailed.CreateFmt(SAssertError, 
      [SAssertionFailed, FileNameOnly, LineNumber]) at ErrorAddr; 
    end; 

begin 
    AssertErrorProc := CustomAssertErrorHandler; 

try 
    Assert(False); 
    except 
    on E: Exception do 
    begin 
     WriteLn(E.ClassName, ': ', E.Message); 
     ReadLn; 
    end; 
    end; 
end. 

---

更新：下面是提問的解決方案，從整個項目的路徑轉換爲相對路徑：

program Project3; 

{$AppType Console} 

{$R *.res} 

uses 
    System.SysConst, 
    System.SysUtils; 

procedure AssertErrorHandler(const Msg, Filename: String; 
    LineNumber: Integer; ErrorAddr: Pointer); 

{$Region '$Include ProjectRoot.pas.inc'} 

const 
    ProjectRoot = 'C:\Users\'; 

{$EndRegion} 

var 
    Temp: String; 

begin 
    if (ProjectRoot <> '') and Filename.StartsWith(ProjectRoot) then 
    Temp := Filename.Remove(0, ProjectRoot.Length) 
    else 
    Temp := ExtractFileName(Filename); 

    if Msg <> '' then 
    raise EAssertionFailed.CreateResFmt(@SAssertError, 
     [Msg, Temp, LineNumber]) at ErrorAddr 
    else 
    raise EAssertionFailed.CreateResFmt(@SAssertError, 
     [SAssertionFailed, Temp, LineNumber]) at ErrorAddr; 
end; 

begin 
    try 
    AssertErrorProc := AssertErrorHandler; 
// Assert(False); 
    Assert(False, 'Custom message'); 
    except 
    on E: Exception do 
    begin 
     WriteLn(E.ClassName, ': ', E.Message); 
     ReadLn; 
    end; 
    end; 
end.