如何將多部分/相關消息發佈到HTTP服務器？

Question

如何將一個multipart/related消息的兩部分發送到HTTP（S）服務器？

我需要這個https://cloud.google.com/storage/docs/json_api/v1/how-tos/multipart-upload

我們使用Perl 5

Answer 1

瞭如何將多部分/相關主體發送到一些網站的一些演示。我不知道這是否會發送完整的Google API所需的數據，但它應該給出您的想法。仍然建議您對MIME有基本的瞭解，特別是MIME中多部分消息的構造（其中multipart/related僅僅是一個例子）和Content-Transfer-Encoding。 Wikipedia entry to MIME可能是一個很好的開始。

use strict; 
use warnings; 
use LWP; 
use MIME::Base64 'encode_base64'; 
use HTTP::Request; 

# Create the parts, each consisting of MIME-Header and body. 
my $part1 = 
    "Content-type: application/json; charset=UTF-8\r\n\r\n". 
    "some json here\r\n"; 
my $part2 = 
    "Content-type: image/gif\r\nContent-Transfer-Encoding: base64\r\n\r\n". 
    encode_base64("...image data here..."); 

# Combine the parts to a single multipart, using the boundary defined later 
# in the Content-Type. 
my $body = 
    "--some-boundary\r\n".  # start of 1st part 
    $part1. 
    "--some-boundary\r\n".  # start of 2nd part 
    $part2. 
    "--some-boundary--\r\n"; # end boundary 

# Create the request. The Content-type is multiplart/related and defines 
# the boundary used to separate the parts. 
my $req = HTTP::Request->new(
    POST => 'http://example.com/api/postit', 
    [ 
     'Content-length' => length($body), 
     'Content-type' => 'multipart/related; boundary="some-boundary"', 
    ], 
    $body 
); 
LWP::UserAgent->new->request($req);