創建一個vbs腳本函數發送電子郵件附件

Question

我是新手腳本和我在openoffice內創建一個自動化的任務我有粗糙的基本語言的問題，但我發現一個用vba寫的excel宏我現在需要我嘗試將其轉換爲可以在命令提示符下的東西，如email.vbs的mailto主題filetoattach

Dim cdoMsg As New CDO.Message 

With cdoMsg 
    With .Configuration.Fields 
     .Item(cdoSendUsingMethod).Value = cdoSendUsingPort 
     .Item(cdoSMTPUseSSL).Value = True 
     .Item(cdoSMTPServerPort).Value = 465 
     .Item(cdoSMTPServer).Value = "smtpserver" 
     .Item(cdoSendUserName).Value = "wolverinewest@wolverinetruckgroup.com" 
     .Item(cdoSendPassword).Value = "mypass" 
     .Item(cdoSMTPAuthenticate).Value = cdoBasic 
     .Update 
    End With 
    .From = "myemail" 
    .To = "emailto" 
    .Subject = "Some more really spiffy mail for you!" 
    .TextBody = "please find attachment" 
    .AddAttachment App.Path & "attachment" 

    On Error Resume Next 
    .Send 
End With 

If Err.Number <> 0 Then 
    MsgBox "CDO error " & Hex$(Err.Number) & vbNewLine & Err.Description, _ 
      vbOKOnly Or vbExclamation, _ 
      Caption 
Else 
    MsgBox "Mail sent!", vbOKOnly, Caption 
End If 

Answer 1

語法在Windows啓動，如果使用WScript的是;

wscript.exe "C:\path\example.vbs" "your email address" "who your sending it to" "your subject" "your body text & vbCRLF & for new line" "c:\path\attachment" 

的「」是必需的，因爲空間通過關秩序和窗口發送錯誤，如果空間是路徑

dim mailto 
dim mailfrom 
dim subject 
dim body 
dim attachment 
mailfrom = WScript.Arguments.Item(0) 
mailto = WScript.Arguments.Item(1) 
subject = WScript.Arguments.Item(2) 
body = WScript.Arguments.Item(3) 
attachment = WScript.Arguments.Item(4) 


Set emailObj  = CreateObject("CDO.Message") 
emailObj.From  = mailfrom 
emailObj.To  = mailto 
emailObj.Subject = subject 
emailObj.TextBody = body 

emailObj.AddAttachment attachment 

Set emailConfig = emailObj.Configuration 

emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.mysmtp.com" 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpusessl")  = true 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = "myUsername" 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "myPassword" 
emailConfig.Fields.Update 

emailObj.Send 

If err.number = 0 then Msgbox "email sent" 

Answer 2

VBScript中執行一個可用的VBScript沒有內置的常量，所以你不得不看的常量在VBA的對象瀏覽器中（Excel中的Alt + F11 - F2）並使用該編號。 VBScript中只有一種數據類型，因此不會調暗任何東西（例如Dim x as string只有Dim x）。 VBscript只能後期綁定所以沒有Dim cdoMsg As New CDO.Message - 必須set cdomsg = CreateObject("cdo.message")。

關於VBScript沒有什麼原油。

字段將具有從Outlook Express或Windows Mail取得的默認值，但不會在Windows 10上設置，因爲它沒有這兩個程序中的任何一個。

這裏的最低限度

Set emailObj  = CreateObject("CDO.Message") 
emailObj.From  = "dcandy@gmail.com" 
emailObj.To  = "dcandy@gmail.com" 
emailObj.Subject = "Test CDO" 
emailObj.TextBody = "Test CDO" 

emailObj.AddAttachment "c:\windows\win.ini" 

Set emailConfig = emailObj.Configuration 

emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com" 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpusessl")  = true 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = "Username" 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "Password" 
emailConfig.Fields.Update 

emailObj.Send 

If err.number = 0 then Msgbox "Done"