ActionScript播放音頻

Question

我只是試圖製作一個簡單的.swf文件，它在加載時播放一段音頻。這個編譯，但是當我把它帶入瀏覽器時什麼也沒有發生。我只能找到基於sprite的教程，所以我採取了一種刺探方式，可以像擴展Sprite一樣擴展Sound。最終的版本將無法正常工作，並稱我的Java Script在事件上播放音頻。

package { 
      import flash.media.Sound; 
      import flash.net.URLRequest; 

      public class typeRight extends Sound { 
        public function HelloWorld() { 
        load(new URLRequest('./sound.mp3')); 
        play(); 
        } 
      } 
    } 

我不在閃存工作所以請不要GUI的建議; ）

Answer 1

而不是繼承Sound類，創建一個文檔類這樣的包含在其中的聲音類：

package 
{ 
    import flash.display.Sprite; 
    import flash.events.Event; 
    import flash.events.IOErrorEvent; 
    import flash.media.Sound; 
    import flash.media.SoundChannel; 
    import flash.net.URLRequest; 

    public class SoundPlayer extends Sprite 
    { 
     protected var _sound : Sound; 
     protected var _channel : SoundChannel; 

     public function SoundPlayer() 
     { 
      _sound = new Sound(); 
      _sound.addEventListener(Event.COMPLETE, soundLoadCompleteHandler); 
      _sound.addEventListener(IOErrorEvent.IO_ERROR, loadError); 
      _sound.load(new URLRequest("./sound.mp3")); 
     } 

     protected function soundLoadCompleteHandler(evt : Event) : void 
     { 
      // Use the _channel object to control sound properties such as pan and volume. 
      _channel = _sound.play(); 
     } 

     protected function loadError(evt : IOErrorEvent) : void 
     { 
      trace ("ERROR :: " + evt); 
      // You could try recovering from the error here. 
     } 

    } 
}