在vba範圍內尋找文本

Question

我有一個範圍，包含不同列中的不同詞，範圍將是DT21：EH400。我想知道是否有一種方法，通過該範圍進行搜索，如果有一個字複製並粘貼到同一行也已開啓，但在B列

Answer 1

下面的代碼可能工作

它搜索範圍內的字，並將搜索詞爲其中搜索詞發現

Dim strSearch as String 
Dim rngData as Range 
Dim rngCell as Range 

strSearch = "Word to Search" 
Set rngData = Range(Cells(21,124),Cells(400,138)) 

For each rngCell in rngData 
    If rngCell.value = strSearch Then 
     cells(rngcell.Row, 2).Value = strSearch 
    End if 
Next rngCell 

Answer 2

在該行的B列的值在查找功能內置應該比自己寫循環更快：

Sub findUsingFIND() 

    Dim searchString As String 
    searchString = Excel.Application.InputBox("Enter string please") 

    Dim targetArea As Range 
    Set targetArea = Excel.Application.InputBox("Select range to search", , , , , , , 8) 

    targetArea.Select 
    'Excel.ThisWorkbook.Sheets(1).Range("DT21:EH400").Select 

    Dim foundRange As Range 
    With targetArea 
     Set foundRange = _ 
      .Find(What:=searchString, _ 
        After:=.Cells(1), _ 
        LookIn:=xlValues, _ 
        LookAt:=xlWhole, _ 
        SearchOrder:=xlByRows, _ 
        SearchDirection:=xlNext, _ 
        MatchCase:=False) 
    End With 

    If Not foundRange Is Nothing Then 
     ThisWorkbook.Sheets(1).Range("B" & foundRange.Row) = searchString 
    Else 
     MsgBox "Nothing found" 
    End If 

End Sub 

如果有字符串，然後上面可以適應於以下幾種情況：

Sub findSeveralUsingFIND() 

    Dim searchString As String 
    searchString = Excel.Application.InputBox("Enter string please") 

    Dim targetArea As Range 
    Set targetArea = Excel.Application.InputBox("Select range to search", , , , , , , 8) 

    targetArea.Select 
    'Excel.ThisWorkbook.Sheets(1).Range("DT21:EH400").Select 

    Dim foundRange As Range 
    With targetArea 
     Set foundRange = _ 
      .Find(What:=searchString, _ 
        After:=.Cells(1), _ 
        LookIn:=xlValues, _ 
        LookAt:=xlWhole, _ 
        SearchOrder:=xlByRows, _ 
        SearchDirection:=xlNext, _ 
        MatchCase:=False) 

     If Not foundRange Is Nothing Then 
      FirstAddress = foundRange.Address 
      Do 
       ThisWorkbook.Sheets(1).Range("B" & foundRange.Row).Value = searchString 
       Set foundRange = .FindNext(foundRange) 
      Loop While Not foundRange Is Nothing And foundRange.Address <> FirstAddress 
     Else 
      MsgBox "Nothing found" 
     End If 

    End With 

End Sub 

由於@ChrisNeilsen指出有一個，如果你需要執行搜索很多，這將是最好非常快的方法倍。這使用數組。我的理解相對較淺，爲什麼這種方法很快，但我相信它與數組將數據存儲在彼此相鄰的一組內存地址中的方式相關。下面是不同的方法良好的比較：

http://fastexcel.wordpress.com/2011/10/26/match-vs-find-vs-variant-array-vba-performance-shootout/

這裏使用的變體類型的數組的宏：

Sub findUsingVARARRAY() 

    Dim vArr As Variant, vRes As Variant 
    Dim j As Long 
    Dim n As Long 

    Dim searchString As String 
    searchString = Excel.Application.InputBox("Enter string please") 

    Dim targetArea As Range 
    Set targetArea = _ 
     Excel.Application.InputBox(prompt:="Select range to search", Type:=8) 

    Dim firstRow As Long 

    vArr = targetArea.Value2 
    ReDim vRes(LBound(vArr, 1) To UBound(vArr, 1), 1 To 1) 
    Dim r As Long, c As Long 
    For r = LBound(vArr, 1) To UBound(vArr, 1) 
    For c = LBound(vArr, 2) To UBound(vArr, 2) 
     ' use vbTextCompare for case insenstitive comapre 
     ' use vbBinaryCompare for case senstitive comapre 
     If StrComp(vArr(r, c), searchString, vbTextCompare) = 0 Then 
      vRes(r, 1) = searchString 
      Exit For 
     End If 
    Next c, r 

    targetArea.EntireRow.Columns(2) = vRes 
End Sub