Neo4j的暗號查詢排序

Question

在我的Neo4j/SDN項目，我有以下模式：包含子Decision和Characteristic實體

Decision實體。

每對兒童Decision和Characteristic可以分配一個Value節點。

我已經在3子Decision節點，例如

childDecision1 
childDecision2 
childDecision3 

和一個Characteristic：

characterisitc1

我已分配下列值以下對：

childDecision2 + characterisitc1 = Value(Integer 10) 
childDecision3 + characterisitc1 = Value(Integer 25) 

我正在執行下面的Cypher查詢（帶O RDER BY sortValue88.value ASC）：

MATCH (parentD)-[:CONTAINS]->(childD:Decision)-[ru:CREATED_BY]->(u:User) 
WHERE id(parentD) = {decisionId} 
OPTIONAL MATCH (childD)<-[:SET_FOR]->(sortValue88:Value)-[:SET_ON]->(sortCharacteristic88:Characteristic) 
WHERE id(sortCharacteristic88) = 88 
WITH ru, u, childD , sortValue88 
ORDER BY sortValue88.value ASC SKIP 0 LIMIT 100 
RETURN ru, u, childD AS decision, [ (parentD)<-[:DEFINED_BY]-(entity)<-[:COMMENTED_ON]-(comg:CommentGroup)-[:COMMENTED_FOR]->(childD) | {entityId: id(entity), types: labels(entity), totalComments: toInt(comg.totalComments)} ] AS commentGroups, [ (parentD)<-[:DEFINED_BY]-(c1:Criterion)<-[:VOTED_ON]-(vg1:VoteGroup)-[:VOTED_FOR]->(childD) | {criterionId: id(c1), weight: vg1.avgVotesWeight, totalVotes: toInt(vg1.totalVotes)} ] AS weightedCriteria, [ (parentD)<-[:DEFINED_BY]-(ch1:Characteristic)<-[:SET_ON]-(v1:Value)-[:SET_FOR]->(childD) | {characteristicId: id(ch1), value: v1.value, valueType: ch1.valueType, visualMode: ch1.visualMode} ] AS valuedCharacteristics 

至於結果，我有：

childDecision2 (Value = 10) 
childDecision3 (Value = 25) 
childDecision1 (no value provided) 

到目前爲止，一切工作正常。

現在我要去的排序順序改變方向從ASC到DESC：

MATCH (parentD)-[:CONTAINS]->(childD:Decision)-[ru:CREATED_BY]->(u:User) 
WHERE id(parentD) = {decisionId} 
OPTIONAL MATCH (childD)<-[:SET_FOR]->(sortValue88:Value)-[:SET_ON]->(sortCharacteristic88:Characteristic) 
WHERE id(sortCharacteristic88) = 88 
WITH ru, u, childD , sortValue88 
ORDER BY sortValue88.value DESC SKIP 0 LIMIT 100 
RETURN ru, u, childD AS decision, [ (parentD)<-[:DEFINED_BY]-(entity)<-[:COMMENTED_ON]-(comg:CommentGroup)-[:COMMENTED_FOR]->(childD) | {entityId: id(entity), types: labels(entity), totalComments: toInt(comg.totalComments)} ] AS commentGroups, [ (parentD)<-[:DEFINED_BY]-(c1:Criterion)<-[:VOTED_ON]-(vg1:VoteGroup)-[:VOTED_FOR]->(childD) | {criterionId: id(c1), weight: vg1.avgVotesWeight, totalVotes: toInt(vg1.totalVotes)} ] AS weightedCriteria, [ (parentD)<-[:DEFINED_BY]-(ch1:Characteristic)<-[:SET_ON]-(v1:Value)-[:SET_FOR]->(childD) | {characteristicId: id(ch1), value: v1.value, valueType: ch1.valueType, visualMode: ch1.visualMode} ] AS valuedCharacteristics 

至於結果，我有：

childDecision1 (no value provided) 
childDecision3 (Value = 25) 
childDecision2 (Value = 10) 

現在我不明白爲什麼childDecision1佔據第一位，但我希望childDecision3代替它。

請你幫忙解釋/解決這個問題嗎？

Answer 1

因爲：When sorting the result set, null will always come at the end of the result set for ascending sorting, and first when doing descending sort.

所以，你需要知道排序的最小可能值。例如，如果所有數值都不小於零，則表示所有數值不小於零。

WITH [1, 0, 2, NULL, 4] AS CS 
UNWIND RANGE(0, size(CS)-1) as i 
RETURN i, 
     CASE WHEN CS[i] IS NULL THEN -1 ELSE CS[i] END AS sortValue 
ORDER BY sortValue DESC