在Delphi中將月份名稱轉換爲數字？

Question

是否有一些內置的Delphi（XE2）/ Windows方法將月份名稱轉換爲數字1-12;而不是自己通過(TFormatSettings.)LongMonthNames[]循環？

Answer 1

您可以使用IndexStr從StrUtils返回-1如果未找到字符串例如

Caption := IntToStr(
    IndexStr(FormatSettings.LongMonthNames[7], FormatSettings.LongMonthNames) + 1); 

編輯：
爲了避免與鑄造和大小寫問題，你可以使用IndexText如圖所示：

Function GetMonthNumber(Const Month:String):Integer; overload; 
begin 
    Result := IndexText(Month,FormatSettings.LongMonthNames)+1 
end; 

Answer 2

我不能找到一種方法，但我寫一個。 ;-)

function GetMonthNumberofName(AMonth: String): Integer; 
var 
    intLoop: Integer; 
begin 
    Result:= -1; 
    if (not AMonth.IsEmpty) then 
    begin 
    for intLoop := Low(System.SysUtils.FormatSettings.LongMonthNames) to High(System.SysUtils.FormatSettings.LongMonthNames) do 
    begin 
     //if System.SysUtils.FormatSettings.LongMonthNames[intLoop]=AMonth then --> see comment about Case insensitive 
     if SameText(System.SysUtils.FormatSettings.LongMonthNames[intLoop], AMonth) then 
     begin 
     Result:= Intloop; 
     Exit 
     end; 
    end; 
    end; 
end; 

好吧，我改變這個功能爲其他FormatSettings。

function GetMonthNumberofName(AMonth: String): Integer; overload; 
function GetMonthNumberofName(AMonth: String; AFormatSettings: TFormatSettings): Integer; overload; 

function GetMonthNumberofName(AMonth: String): Integer; 
begin 
    Result:= GetMonthNumberofName(AMonth, System.SysUtils.FormatSettings); 
end; 

function GetMonthNumberofName(AMonth: String; AFormatSettings: TFormatSettings): Integer; 
var 
    intLoop: Integer; 
begin 
    Result:= -1; 
    if (not AMonth.IsEmpty) then 
    begin 
    for intLoop := Low(AFormatSettings.LongMonthNames) to High(AFormatSettings.LongMonthNames) do 
    begin 
     if SameText(AFormatSettings.LongMonthNames[intLoop], AMonth) then 
     begin 
     Result:= Intloop; 
     Exit 
     end; 
    end; 
    end; 
end; 

與電話系統formatsetting

GetMonthNumberofName('may'); 

或FormatSetting

procedure TForm1.Button4Click(Sender: TObject); 
var 
    iMonth: Integer; 
    oSettings:TFormatSettings; 
begin 
    // Ned 
    // oSettings:= TFormatSettings.Create(2067); 
    // Fr 
    // oSettings:= TFormatSettings.Create(1036); 
    // Eng 
    oSettings:= TFormatSettings.Create(2057); 
    iMonth:= GetMonthNumberofName(self.Edit1.Text, oSettings); 
    showmessage(IntToStr(iMonth)); 
end;