根據csv使用linux將文件拆分爲可變數量和目錄

Question

我有一個包含目錄列表的電子表格，並且需要將相關的可變數量的「帳戶」分配給每個目錄（可以輕鬆轉換爲csv）即：

directory     # of accounts needed 
/usr/src/Mon-Carlton/  110 
/usr/src/Mon-CoalMtn/  50                      
/usr/src/Mon-Cumming/  90 
etc... 

我也有包含要分散到各個區域提供所有可能的帳戶的完整列表中的「master_account_list.csv」文件，即：

account_1,password,type 
account_2,password,type 
account_3,password,type 
etc... 

我想能夠腳本將master_account_list.csv拆分爲分隔符e accounts.csv文件的每個唯一目錄與所需的帳戶數量。

master_file經常使用新帳戶進行更新，並且需要重新分配給所有目錄。 （生成的accounts.csv文件與master_account_list具有相同的格式。）

在Linux中完成的最佳方式是什麼？

編輯：當腳本完成時，如果master_account_list.csv中剩餘的未分配帳戶成爲新的master_account_list.csv，那將是理想的。

Answer 1

假定你已經轉換帳戶spreasheet以逗號分隔的CSV文件，沒有頭，你可以使用下面的awk程序（！）（！）：

split_accounts.awk：

# True as long as we are reading the first file which 
# is the converted spreadsheet 
NR==FNR { 
    # Store the directories and counts in arrays 
    dir[NR]=$1 
    cnt[NR]=$2 
    next 
} 

# This block runs for every line of master_account_list.csv 
{ 
    # Get the directory and count from the arrays we've 
    # created above. 'i' will get initialized automatically 
    # with 0 on it's first usage 
    d=dir[i+1] 
    c=cnt[i+1] 

    # append the current line to the output file 
    f=d"account_list.csv" 
    print >> f 

    # 'n' holds the number of accounts placed into the current 
    # directory. Check if it has the reached the desired count 
    if(++n==c) { 
     # Step to the next folder/count 
     i++ 
     # Reset the number of accounts placed 
     n=0 
     # Close the previous output file 
     close(f) 
    } 
} 

這樣稱呼它：

awk -F, -f split_accounts.awk accounts.csv master_account_list.csv 

注：0是不允許的計入當前的實施。