不能使用合併中的foreach對存在的節點

Question

我期待他下面的查詢由給定的源節點創建節點（僅出口）和關係（1）和一個列表（2）這種方式：

MERGE (p1:C9{userId: '1'}) WITH p1, [{userId:"2"}] AS users 
FOREACH (user IN users | MERGE 
((p1)-[r1:follow]->(:C9 {userId: user.userId}))) 

那是結果：

現在，如果我被交換節點ID這樣再次執行這個查詢：

MERGE (p1:C9{userId: '2'}) WITH p1, [{userId:"1"}] AS users 
    FOREACH (user IN users | MERGE 
    ((p1)-[r1:follow]->(:C9 {userId: user.userId}))) 

我們拿到的這款：

Neo4j的複製我的節點使用id = 1。我希望它在現有節點的情況下合併。

我期望看到只有兩個節點通過合併已有節點相互連接。

任何想法我應該修復？

謝謝， 射線。

Answer 1

我通常會避免FOREACH時，我可以使用UNWIND，所以我會像這樣開始：

MERGE (p1:C9 {userId: '1'}) 
WITH p1, [{userId:"2"}] AS users 
UNWIND users AS user 
MERGE (p1)-[r1:follow]->(:C9 {userId: user.userId}) 

有時你也想你的節點創建從你的關係創建分開。如果你同時做這兩件事，我認爲Neo4j可以認爲你想要一個節點（包含屬性）和關係的獨特組合。

MERGE (p1:C9 {userId: '1'}) 
WITH p1, [{userId:"2"}] AS users 
UNWIND users AS user 
MERGE (p2:C9 {userId: user.userId}) 
MERGE (p1)-[r1:follow]->(p2) 

Answer 2

可以內FOREACH使用MERGE。

但是你必須瞭解MERGE的語義。它試圖MATCH一個完整的模式，如果它沒有找到它它將完全CREATE該模式。

你在你的情況下，你嘗試在p1的上下文內找到的模式，而不是全局的，如果沒有找到，它會在p1的上下文中創建它。

所以，如果你改變你的查詢：

MERGE (p1:C9{userId: '2'}) 
WITH p1, [{userId:"1"}] AS users 
FOREACH (user IN users | 
    MERGE (p2:C9 {userId: user.userId}) 
    MERGE (p1)-[r1:follow]->(p2) 
) 

即先創建p2再與MERGE的關係，它會起作用。