XSL唯一值

Question

好吧，我有這個XML

<roots> 
<root> 
    <name>first</name> 
    <item type='test'><something>A</something></item> 
    <item type='test'><something>B</something></item> 
    <item type='test'><something>C</something></item> 
    <item type='test'><something>A</something></item> 
    <item type='other'><something>A</something></item> 
    <item type='test'><something>B</something></item> 
    <item type='other'><something>D</something></item> 

</root> 
<root> 
<name>second</name> 
    <item type='test'><something>E</something></item> 
    <item type='test'><something>B</something></item> 
    <item type='test'><something>F</something></item> 
    <item type='test'><something>A</something></item> 
    <item type='other'><something>A</something></item> 
    <item type='test'><something>B</something></item> 
    <item type='other'><something>D</something></item> 

</root> 

</roots> 

現在我需要得到各根節點的唯一值到目前爲止，我已經

<?xml version="1.0" encoding="ISO-8859-1"?> 
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:output indent="yes" method="text"/> 
    <xsl:key name="item-by-value" match="something" use="."/> 
    <xsl:key name="rootkey" match="root" use="name"/> 

    <xsl:template match="/"> 
    <xsl:for-each select="key('rootkey','second')"> 
     <xsl:for-each select="item/something"> 
     <xsl:if test="generate-id() = generate-id(key('item-by-value', normalize-space(.)))"> 
      <xsl:value-of select="."/> 
     </xsl:if> 
     </xsl:for-each> 
    </xsl:for-each> 
    </xsl:template> 

</xsl:stylesheet> 

如果我使用「第一」關鍵只得到第一根我得到一個好的結果ABCD

我怎麼過，如果我使用「第二」我只得到EF但需要得到的結果是ABDFE

Answer 1

我得到EBFAD對你的xsl進行了一些修改。關鍵在於，如果您使用密鑰在給定根元素下查找包含此內容的第一個節點，則該密鑰需要特定於根元素。我改變了xsl:key到：

<xsl:key name="item-by-value" match="something" 
use="concat(normalize-space(.), ' ', generate-id(./ancestor::root))"/> 

然後xsl:if測試變爲：

<xsl:if test="generate-id() = generate-id(key('item-by-value', 
        concat(normalize-space(.), ' ', generate-id(./ancestor::root))))"> 

Answer 2

我覺得你很親密。但是，你只需要擁有正確的根作爲父項目按值鍵的第一個值：

<xsl:for-each select="key('rootkey','second')"> 
    <xsl:variable name="root" select="generate-id()" /> 
    <xsl:for-each select="item/something"> 
     <xsl:sort order="ascending" select="." data-type="text"/> 
     <xsl:if test="generate-id() = generate-id(key('item-by-value', .)[generate-id(ancestor::root)=$root][1])"> 
      <xsl:value-of select="."/> 
     </xsl:if> 
    </xsl:for-each> 
</xsl:for-each> 

Answer 3

這是你必須使用一個複合鍵的情況。

該轉化：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text"/> 

<xsl:key name="kSomethingByNameAndVal" match="something" 
    use="concat(../../name, '+', .)"/> 

<xsl:template match="/"> 
    <xsl:for-each select="*/*"> 
    <xsl:for-each select= 
     "item/something 
      [generate-id() 
      = 
       generate-id(key('kSomethingByNameAndVal', 
           concat(../../name, '+', .) 
          ) 
         ) 
      ] 
     "> 

     <xsl:value-of select="."/> 
    </xsl:for-each> 
    <xsl:text>&#xA;</xsl:text> 
    </xsl:for-each> 
</xsl:template> 
</xsl:stylesheet> 

當所提供的XML文檔施加正確地產生希望的結果：

ABCD

EBFAD