語法參數指向語法模式變量？

Question

的syntax-parameterize結合通常用於與make-rename-transformer使得語法參數p表現爲另一標識符的別名：

#lang racket 

(require racket/stxparam) 
(define-syntax-parameter p #f) 

(define-syntax (test-1-p stx) 
    (syntax-case stx() 
    [(_ body) 
    #'(let ([tmp 123]) 
     (syntax-parameterize ([p (make-rename-transformer #'tmp)]) 
      body))])) 
(test-1-p p) ;; prints 123 

上面的代碼工作得很好，因爲tmp是由let結合的標識符。但是，如果我試圖讓p由with-syntax綁定的模式變量tmp一個別名，那麼它並不會達到預期效果：

#lang racket 

(require racket/stxparam) 
(define-syntax-parameter p #f) 

(define-syntax (test-2-p stx) 
    (syntax-case stx() 
    [(_ body) 
    #'(with-syntax ([tmp #'(foo 123)]) 
     (syntax-parameterize ([p (make-rename-transformer #'tmp)]) 
      body))])) 
(test-2-p #'p) ;; gives #'p, instead of #'(foo 123) 

相反，如果我宣佈一個p-unhygienic語法，並將其綁定到(make-rename-transformer #'tmp)，那麼它的工作原理細：

#lang racket 

(define-syntax (test-3-p stx) 
    (syntax-case stx() 
    [(_ body) 
    #`(with-syntax ([tmp #'(foo 123)]) 
     (define-syntax #,(syntax-local-introduce #'p-unhygienic) 
      (make-rename-transformer #'tmp)) 
     body)])) 
(test-3-p #'p-unhygienic) ;; gives #'(foo 123), as expected 

如何使用syntax-parameterize爲模式變量創建一個衛生別名？

Answer 1

這是一個有趣的案例，我期待你做同樣的事情。這可能是某處或某處的缺陷;我不確定。無論採用哪種方式，都提供了define-rename-transformer-parameter表單作爲解決方法。

重命名變換器參數的初始值必須是重命名變換器，因此您可以使用p-init標識符和#f作爲變換器綁定。

(define-syntax p-init #f) 
(define-rename-transformer-parameter p (make-rename-transformer #'p-init)) 

在背景：

#lang racket 

(require racket/stxparam) 
(define-syntax p-init #f) 
(define-rename-transformer-parameter p (make-rename-transformer #'p-init)) 

(define-syntax (test-2-p stx) 
    (syntax-case stx() 
    [(_ body) 
    #'(with-syntax ([tmp #'(foo 123)]) 
     (syntax-parameterize ([p (make-rename-transformer #'tmp)]) 
      body))])) 
(test-2-p #'p) ; #<syntax:10:28 (foo 123)>