對話框操作

Question

我想創建一個對話窗口，用戶可以在其中執行各種任務，並希望他通過用鼠標單擊Cancel按鈕（即不按Enter）從對話框返回。因此我不想使用CreateDialog。但是，通過CreateWindow創建一個不太明確的對話框窗口，所有字符串都顯示爲未格式化。

expr = Column[{ 
    Row@{"set variable to: ", InputField["value", String]}, 
    "Try to hit Enter in any of the dialogs: it closes #2 but not #1.", 
    CancelButton[] 
    }]; 

CreateWindow[DialogNotebook[expr], WindowSize -> All, WindowMargins -> {{100, Automatic}, {Automatic, Automatic}}, WindowTitle -> "1. CreateWindow & DialogNotebook"]; 
CreateDialog[expr, WindowTitle -> "2. CreateDialog"]; 

有沒有什麼聰明的辦法有第二對話窗口的外觀，但第一個的按鈕的行爲？當然，expr這裏是一個簡單的例子，但它在現實中可能相當複雜，因此它不可能將每個字符串包裝到Cell[string, "Text"]中，而將每個其他表達式包裝到一些不太明確的boxform中。

Answer 1

被按下時，輸入這會阻止你的對話窗口關閉：

CreateDialog[expr, WindowTitle -> "2. CreateDialog", NotebookEventActions -> {}]; 

它覆蓋默認對話框NotebookEventActions。

Answer 2

也許使用TextCell：

expr = Column[{Row@{TextCell@"set variable to: ", 
        InputField["value", String]}, 
       TextCell@"Try to hit Enter in any of the dialogs: \ 
         it closes #2 but not #1.", 
       CancelButton[]}]; 

CreateWindow[ 
DialogNotebook[expr], WindowSize -> All, 
WindowMargins -> {{100, Automatic}, {Automatic, Automatic}}, 
WindowTitle -> "1. CreateWindow & DialogNotebook"] 

編輯

使用

TextCell@Style[" ... blah blah ...", style_opt ] 

進行格式化。

Answer 3

另一種選擇：

expr = Style[ 
    Column[{Row@{"set variable to: ", InputField["value", String]}, 
    "Try to hit Enter in any of the dialogs: it closes #2 but not \ 
#1.", CancelButton[]}], ShowStringCharacters -> False]; 

Answer 4

有許多方法可以做到這一點，和其他人已經發布了兩個好的，但在我看來，最簡單的方法是將Column表達BaseStyle設爲匹配對話框的基礎樣式，然後使用CreateWindow。有問題的風格是"Panel"，所以這讓你你想要的結果：

expr = Column[{Row@{"set variable to: ", InputField["value", String]}, 
    "Try to hit Enter in any of the dialogs: it closes #2 but not #1.", 
    CancelButton[]}, BaseStyle -> "Panel"]; 

CreateWindow[DialogNotebook[expr], WindowSize -> All, 
    WindowMargins -> {{100, Automatic}, {Automatic, Automatic}}, 
    WindowTitle -> "1. CreateWindow & DialogNotebook"];