如何對數組進行排序，以便某些文件擴展名排在最前面？

Question

我有一個包含文件列表的數組。我想對它進行排序，讓它在數組的開頭和文件的其餘部分都有.txt文件。

這就是我現在正在做的，它工作正常。

@files = (grep(/\.txt$/,@files),grep(!/\.txt$/,@files)); 

有沒有更好的方法來做到這一點呢？

Answer 1

Sort將可選塊作爲第一個參數，儘管在這種情況下Schwartzian變換會更快。

@files = map { $_->[0] } sort { $a->[1] <=> $b->[1] } map { [ $_, !/\.txt$/ ] } @files; 

Answer 2

你只需要在每個grep S的前面加上sort：

my @sorted = 
    (
    sort(grep /\.txt\z/, @files), 
    sort(grep ! /\.txt\z/, @files) 
    ); 

這裏的技巧是，你是分區列表，然後獨立分揀每個分區。根據你在做什麼，這可能比嘗試在一個排序操作中做所有事情要好得多。相反，它可能並不總是更好。

有很多其他的方式來完成這件事，但他們不是這麼簡單。 :)

這裏有一個快速的基準上我的MacBook Air與香草的Perl 5.10.1：

There are 600 files to sort 
    brian: 3 wallclock secs @ 369.75/s (n=1161) 
    control: 3 wallclock secs @ 1811.99/s (n=5744) 
     leon: 4 wallclock secs @ 146.98/s (n=463) 
    mobrule: 3 wallclock secs @ 101.57/s (n=324) 
     sort: 4 wallclock secs @ 559.62/s (n=1746) 

這裏的腳本：

use Benchmark; 

use vars qw(@files); 

@files = qw(
    buster.pdf 
    mimi.xls 
    roscoe.doc 
    buster.txt 
    mimi.txt 
    roscoe.txt 
    ) x 100; 


printf "There are %d files to sort\n", scalar @files; 

sub leon { 
    my @sorted = 
     map { $_->[0] } 
     sort { $a->[1] <=> $b->[1] } 
     map { [ $_, !/\.txt$/ ] 
     } @files; 
    } 

sub brian { 
    my @sorted = 
     (
     sort(grep /\.txt\z/, @files), 
     sort(grep ! /\.txt\z/, @files) 
     ); 
    } 

sub mobrule { 
    my @sorted = 
     sort { ($b=~/\.txt\z/) <=> ($a=~/\.txt\z/) || $a cmp $b } 
     @files; 
    } 

sub plain_sort { 
    my @sorted = sort @files; 
    } 

sub control { 
    my @sorted = @files; 
    } 

timethese(-3, 
    { 
    brian => \&brian, 
    leon => \&leon, 
    mobrule => \&mobrule, 
    control => \&control, 
    sort => \&plain_sort, 
    } 
    ); 

Answer 3

 

@sorted = sort { $b=~/\.txt$/ <=> $a=~/\.txt$/ || $a cmp $b } @files 

會放。 txt文件，並按照字典順序排列（按字母順序排列）。

@sorted = sort { $b=~/\.txt$/ <=> $a=~/\.txt$/ } @files 

會先將.txt文件否則保留原來的順序（sort是因爲Perl 5.8 穩定）

Answer 4

代碼高爾夫？ 這不會產生討厭的警告：

@files = map { $_->[0] } sort { @$b <=> @$a } map { [$_, /\.txt$/] } @files 

Answer 5

你問到這樣一個以上的文件擴展名的後續評論。在那種情況下，我會建立Schwartzian變換。如果你是ST的新手，我建議Joseph Hall的解釋在有效的Perl編程。儘管Second Edition即將推出，但我們基本上保留了他的解釋，因此first edition也一樣好。谷歌圖書似乎只在第一版每頁顯示一英寸，所以你在那裏運氣不好。

在這個答案中，我使用加權函數來決定哪些擴展應該移動到頂部。如果一個擴展沒有明確的權重，我只是用文字排序。你可以欺騙與周圍的sort得到正是你想要的順序：

@files = qw(
    buster.pdf 
    mimi.xls 
    roscoe.doc 
    buster.txt 
    mimi.txt 
    roscoe.txt 
    buster.rpm 
    mimi.rpm 
    ); 

my %weights = qw(
    txt 10 
    rpm 9 
    ); 

my @sorted = 
    map { $_->{name} } 
    sort { 
     $b->{weight} <=> $a->{weight} 
     || 
     $a->{ext} cmp $b->{ext} 
     || 
     $a cmp $b 
     } 
    map { 
     my($ext) = /\.([^.]+)\z/; 
      { # anonymous hash constructor 
      name => $_, 
      ext => $ext, 
      weight => $weights{$ext} || 0, 
      } 
     } 
    @files; 

$" = "\n"; 
print "@sorted\n"; 

Answer 6

高效處理多個擴展，你可以通過在一個通分割你的陣列修改布賴恩·d FOY的分類grep s，然後排序每個獨立分區。

use strict; 
use warnings; 

use List::MoreUtils qw(part); 

my @files = qw(
    bar  Bar.pm  bar.txt 
    bar.jpeg foo   foo.pm 
    foo.jpeg zebra.txt zebra.pm 
    foo.bat foo.c  foo.pl 
    Foo.pm  foo.png  foo.tt 
    orange  apple  zebra.stripe 
); 


my @parts = part { get_extension_priority($_) } @files; 

my @sorted = map { sort(@{ $_ || [] }) } @parts; 

print map "$_\n", @sorted; 

BEGIN { 

    # Set extension priority order 
    my @priority = qw(stripe txt nomatch pl jpeg ); 

    # make a hash to look up priority by extension 
    my %p = map { $priority[$_], $_ } 0..$#priority; 

    sub get_extension_priority { 
     my $file = shift; 

     return scalar @priority 
      unless /[.](\w*)$/; 

     return scalar @priority 
      unless exists $p{$1}; 

     return $p{$1}; 
    } 
}