如何在x86彙編中劃分浮點數？

Question

當我嘗試寫鷺算法來計算來自ECX寄存器的sqrt時，它不起作用。看起來問題是將浮點數分開，因爲結果是整數。

我的算法：

sqrtecx: 

MOV EDX, 10 ; loop count 
MOV EAX, 5 ; x_0 in heron algorythm 
MOV DWORD[EBP-100], ECX ; save INPUT (ecx is input)  
MOV DWORD[EBP-104], EDX ; save loop count 
jmp  loop 
MOV  ECX, EAX ; move OUTPUT to ECX 

loop: 

MOV DWORD[EBP-104], EDX ; save loop count 
xor edx, edx 

MOV ECX, EAX 
MOV  EAX, DWORD[EBP-100] 
DIV ECX 
ADD EAX, ECX 
XOR EDX, EDX 
mov ecx, 2 
DIV ecx 

MOV EDX, DWORD[EBP-104] ; load loop count 
DEC EDX 
JNZ loop 

Answer 1

DIV是整數除法 - 你需要FDIV浮點（或更可能FIDIV在這種特殊情況下，因爲它看起來像你開始用一個整數值）。

Answer 2

您需要使用浮點指令集來實現您的目標。你可能會發現一些有用的指令是：

fild <int> - loads and integer into st0 (not an immediate 
faddp  - adds st0 to st1, and pop from reg stack (i.e. result in st0) 
fdivp  - divides st0 by st1, then pop from reg stack (again, result in st0) 

這裏有一個簡單的例子片斷（VS2010聯彙編）：

int main(void) 
{ 
    float res; 

    __asm { 
     push dword ptr 5;  // fild needs a memory location, the trick is 
     fild [esp];   // to use the stack as a temp. storage 
     fild [esp];   // now st0 and st1 both contain (float) 5 
     add  esp, 4;   // better not screw up the stack 
     fadd st(0), st(0); // st0 = st0 + st0 = 10 
     fdivp st(1), st(0); // st0 = st1/st0 = 5/10 = 0.5 
     sub  esp, 4;   // again, let's make some room on the stack 
     fstp [esp];   // store the content of st0 into [esp] 
     pop  eax;    // get 0.5 off the stack 
     mov  res, eax;  // move it into res (main's local var) 
     add  esp, 4;   // preserve the stack 
    } 

    printf("res is %f", res); // write the result (0.5) 
} 

編輯：
正如哈羅德指出的那樣，也是其計算的指令直接的平方根，它是fsqrt。操作數和結果都是st0。

編輯＃2：
我不知道你是否真的可以加載到st0立即值作爲我reference不一樣，如果明確規定。因此，我做了一個小片段來檢查，結果是：

float res = 5.0 * 3 - 1; 
000313BE D9 05 A8 57 03 00 fld   dword ptr [__real@41600000 (357A8h)] 
000313C4 D9 5D F8    fstp  dword ptr [res] 

這些字節在357A8h：

__real@41600000: 
000357A8 00 00    add   byte ptr [eax],al 
000357AA 60     pushad 
000357AB 41     inc   ecx 

所以我不得不得出結論，不幸的是，你必須在一些地方保存你的號碼在加載和存儲它們時都在主存中。當然，按照我上面的建議使用堆棧並不是強制性的，實際上你也可以在你的數據段或其他地方定義一些變量。

編輯＃3：
別擔心，組裝是一個強大的野獸打;）關於你的代碼：

mov  ecx, 169 ; the number with i wanna to root 
sub  esp, 100 ; i move esp for free space 
push ecx   ; i save value of ecx 
add  esp,4  ; push was move my ebp,then i must come back 
fld     ; i load from esp, then i should load ecx 
fsqrt    ; i sqrt it 
fst     ; i save it on ebp+100 
add  esp,100  ; back esp to ebp 

你錯過的fld和fst操作數。看看你的意見，我想你想要fld [esp]和fst [esp]，我不明白你爲什麼談論ebp。 ebp應該保存堆棧框架的開始（其中有很多我們不應該搞砸的東西），而esp則包含它的結尾。我們基本上希望在堆棧框架結束時進行操作，因爲在它之後只有垃圾沒有人關心。
在計算並保存平方根後，您還應該在末尾add esp, 4。這是因爲push ecx確實也在sub esp, 4之下爲您推送的價值騰出空間，並且在將價值保存回來時仍需要一些空間。只是爲了這個，你也可以避免sub esp, 100和add esp, 100，因爲房間已經由push爲你製造了。
最後一個「警告」：整數和浮點值的表示方式非常不同，因此當您知道必須使用這兩種類型時，請小心所選的說明。您建議的代碼使用fld和fst，它們都使用浮點值進行操作，所以得到的結果不會成爲您期望的結果。一個例子？ 00 00 00 A9是169上的字節表示，但它表示浮點數+ 2.3681944047089408e-0043（對於那些挑剔的人來說它實際上是一個長整數）。
所以，最終的代碼是：

mov  ecx, 169; // the number which we wanna root 
push ecx;  // save it on the stack 
fild [esp];  // load into st0 
fsqrt;    // find the square root 
fistp [esp];  // save it back on stack (as an integer) 
// or fst [esp] for saving it as a float 
pop ecx;   // get it back in ecx 

Answer 3

我不能完全確定你真正想做的事，所以現在我會假設你要取的整數浮點平方根。

mov dword ptr[esp],ecx ; can't load a GRP onto the FPU stack, so go through mem 
fild dword ptr[esp]  ; read it back (as integer, converted to float) 
fsqrt     ; take the square root 

第一個dword ptr可能是可選的，這取決於您的彙編程序。

在此代碼之後，結果位於FPU堆棧ST（0）的頂部。我不知道你想用事後它做什麼..如果你想將它四捨五入爲int，並把它背在ECX，我建議這樣的：

fistp dword ptr[esp]  ; again it can't go directly, it has to go through mem 
mov ecx,dword ptr[esp] 

我將在SSE2扔好辦法的方法：

cvtsi2sd xmm0,ecx ; convert int to double 
sqrtsd xmm0,xmm0 ; take the square root 
cvtsd2si ecx,xmm0 ; round back to int (cvttsd2si for truncate instead of round) 

這樣更容易一些。