通過VBA在Access前端執行MySQL存儲過程

Question

因此，數據庫hotchpotch。

• 我有一個存儲過程的MySQL數據庫。
• 我有一個連接到MySQL數據庫（我可以調查表）的Access文件作爲前端（與形式和東西）
• 我已經成功創建了一個ODBC通過查詢（我認爲這就是他們是什麼調用）從數據庫調用其中一個存儲過程。在訪問查詢實際上只是CALL myProcName;，給我我希望當我Set Result = CurrentDb.OpenRecordset("myProcName")

把它從VBA的結果是什麼，我想實現如下：

• 已經在存儲過程需要一個參數的MySQL =>檢查！
• 讓該存儲過程按預期工作=>在phpMyAdmin中檢查=>檢查！
• 在Access中保存了一個查詢，該查詢鏈接到此參數存儲過程並給定固定參數值=>檢查！ （CALL myProcName('myParameterValue')，我可以調用從VBA，就像我做的unparametric查詢）
• 必須指定'myParameterValue'每次我執行能力的查詢=>不檢查

我需要以某種方式指定的參數在保存的查詢的SQL定義中添加佔位符，並在VBA中設置該參數。對於VBA部分我有和想法，我會發現相當優雅：

Private Sub ParametricQuery() 
    Dim QDef As QueryDef 
    Set QDef = CurrentDb.QueryDefs("myProcName") 
    QDef.Parameters(*insert parameter name here*) = parameter value 
    Dim Result As Recordset 
    Set Result = QDef.OpenRecordset 

    Do While Not Result.EOF 
    MsgBox Result.Fields(1) 'Display a field from the results 
    Loop 
End Sub 

但我將如何建立我的SQL定義？

PARAMETERS in_param TEXT; 
CALL myProcName(in_param); 

不起作用。如果我嘗試

Set QDef = CurrentDb.QueryDefs("myProcName") 
MsgBox QDef.Parameters.Count 

我得到一個消息框，告訴我有一個總的在我的查詢定義0參數是，這樣是行不通的。

我在網上找到的是很多人通過字符串操作在VBA中構建實際的SQL。這讓我不寒而慄，原因很多（安全性，可維護性和優雅性）。我堅信有一種更好的方式，希望能夠按照我上面所描述的方式。唯一的問題是：如何做到這一點？

Answer 1

考慮使用ADO作爲參數化查詢來調用存儲過程。目前，您正在使用DAO（Access的默認數據庫API）來訪問傳遞查詢（保存的Access querydef）。但是，這種類型的查詢在前端沒有看到任何內容，只有後端RDMS，特別是MySQL SQL方言及其連接的數據庫對象。因此，您不能將本地參數值綁定到它。而PARAMETERS子句只是Access SQL方言的一部分，並且會失敗MySQL語法。

MySQL的存儲過程

CREATE PROCEDURE `mystoredproc`(IN param VARCHAR(254)) 
BEGIN 
    SELECT * FROM table WHERE field=param; 
END 

ADO參數化查詢

Public Sub CallMySQLProc()  
    Dim conn As Object, cmd As Object, rst As Object 
    Const adCmdStoredProc = 4, adParamInput = 1, adVarChar = 200 

    Set conn = CreateObject("ADODB.Connection") 
    Set rst = CreateObject("ADODB.Recordset") 

    ' DSN-LESS CONNECTION 
    conn.Open "Driver={MySQL ODBC 5.3 Unicode Driver};host=hostname;database=databasename;" _ 
       & "UID=username;PWD=****" 

    ' CONFIGURE ADO COMMAND 
    Set cmd = CreateObject("ADODB.Command") 
    With cmd 
     .ActiveConnection = conn 
     .CommandText = "mystoredproc" 
     .CommandType = adCmdStoredProc 
     .CommandTimeout = 15 
    End With 

    ' APPEND NAMED PARAM 
    cmd.Parameters.Append cmd.CreateParameter("param", adVarChar, _ 
               adParamInput, 254, "some.name@example.com") 
    Set rst = cmd.Execute 

    ' FREE RESOURCES 
    rst.Close 
    Set rst = Nothing 
    Set cmd = Nothing 
    Set conn = Nothing 

End Sub 

---

DAO動態傳遞查詢

在這裏，你可以動態生成的QueryDef的.SQL聲明，但不會進行參數設置：

Private Sub ParametricQuery() 
    Dim QDef As QueryDef 
    Dim Result As Recordset 

    Set QDef = CurrentDb.QueryDefs("PassThruQ") 
    QDef.SQL = "CALL mystoredproc('some.name@example.com')" 

    Set Result = QDef.OpenRecordset 

    Do While Not Result.EOF 
    Debug.Print Result.Fields(1) 'Print to immediate window a field from the results 
    Loop 

    Result.close 
    Set Result = Nothing 
    Set QDef = Nothing 
End Sub