查找多個文件的公共密鑰和不同的值存儲到一個數組，並計算不同

Question

我很新的Perl和有，我想通過Perl來完成一項任務：

我有很多的文件看起來像這樣的：（空間deliminated，每個人都有行6列，數千;所有文件以* .hgt結束）

example.hgt

ID  NAMES   Test1  Test2  Percentage  Height 
1  abc10A   B   0.21   165 
1  abc40A   B   0.99   162 
1  abc30C   B   0.107   165 
1  abc20A   E   0.31   167 
1  abc50A   B   0.7    165 
.... 

每個名字在每個.hgt文件是唯一的。我想找到所有.hgt文件中常見的NAMES，並提取所有百分比，並找出最高和最低數字之間的最大差異。

例如，如果我有5個.hgt文件，並且它們都包含NAMES = abc300123，並且相應的百分比是：0.107,0.1,0.4,0.9,0.8，那麼abc300123的最大差異應該是0.9 - 0.1 = 0.8

然後我想輸出NAMES和與從我的所有文件計算出來的NAMES相關的最大差異。輸出的順序按最大差異排序。每行前面有一個整數（0,1,2,3，...）。一個例子是這樣的：

輸出

0. abc50.1 
1. abc90.3 
2. abc10.7 
3. abc30.8 
4. abc11.9 
.... 

我試圖通過每個文件中讀取並存儲在密鑰=名稱和值=百分比成陣列。我想對Percentage數組進行排序，並將最大值和最小值存儲到新數組中，並進行負數計算。有些時候我陷入了困境，無法把事情放在一起。

這裏是我寫到目前爲止：

open(PIPEFROM, "ls *.hgt |") or die "no \.hgt files founded\!\n"; ## find the files that are ended with hgt 
$i=0; 
@filenames = ""; 

while($temp = <PIPEFROM>){ 

    $temp =~ m/\.hgt/; 
    print out "$temp"; 
    $pre = $`; #gives file name without the dot and the hgt extension 
    $filenames[$i] = $pre; 
    $i++; 
} 


%hash =(); 
$j=0; 
## read in files ended with .hgt 
for ($i = 0; $i<=$filenames; $i++) { 
$temp = $filenames[$i]; 

open(PIPETO, "cat $temp.hgt |") or die "no \.hgt files founded\!\n"; 

<PIPETO>; 
while ($temp2 = <PIPETO>){ 
    chomp $temp2; 
    $temp2 = ~ s/^\s+//; 
    @lst = split(/\s+/, $temp2); 
    $NAMES = $lst[1]; 
    $Percentage = $lst[4]; 
    $hash{$NAMES} .= $Percentage . " "; 
} 
} 
### manipulate the values 
foreach $key (sort keys %hash){ 

    @values = split(/\s+/, $hash{$key}); 
    if ($#values == $#filenames){ 
    print "$j" . "\." . " " . "$key" . "\n"; 
    $j++; 
         ### got stuck 
} 
} 

我想包括到這個問題，但我不知道在哪裏把它：

my ($smallest, $largest) = (sort {$a <=> $b} @array)[0,-1]; 

這是如此令人沮喪的。任何形式的幫助將不勝感激！

Answer 1

指定正是這個程序的作用：

# output.pl 
# save this entire script as output.pl 
# obtain output by running this command: 
# 
# cat *.hgt | perl output.pl | more 
# (in order to scroll the results--press "q" in order to quit) 
# 
# cat *.hgt | perl output.pl > results-largest-differences-output-$$.txt 
# in order to create a temporary results file 
# 
# BE CAREFUL because the second command overwrites whatever is in 
# the output file using the ">" operator! 
my %names; 
my $maxcount = `ls *.hgt | wc -l`; 
my %counts; 
while (<>) { 
my @fields = (m/(\S+)/g); 
my $name = $fields[1]; 
my $perc = $fields[4]; 
next if $perc =~ m/[^.\d]/; 
next unless $perc; 
my $t = ($names{$name} ||= [1, 0]); 
# initialize min to as high as possible and max to as low as possible 
$t->[0] = $perc if $perc < $t->[0]; 
$t->[1] = $perc if $perc > $t->[1]; 
$counts{$name}++; # n.b. undef is auto-initialized to 0 before ++ 
} 

for (keys %names) { 
$names{$_} = $names{$_}->[1] - $names{$_}->[0]; 
} 

my $n = 0; 
for (sort { $names{$a} <=> $names{$b} || $a cmp $b } keys %names) { 
next unless $counts{$_} == $maxcount; 
$n++; 
printf("%6s %20s %.2f\n", $n, $_, $names{$_}); 
} 

Answer 2

大廈約瑟夫·邁爾斯的答覆，我做了一些改動，以回答有關如何獲得只發生在所有文件的數據，如何的問題跳過標題行（輸入文件中的行＃1），並將輸出按最大百分比排序爲最小值，並在百分比相等時按名稱排序。運行程序的命令行條目如下所示：

perl output.pl *.hgt。

my $file_count = @ARGV or die "invoke program as:\nperl $0 *.hgt\n";

這在所有的* .hgt到@ARGV陣列，讀取（而不是通過管道貓將其看成自己的程序一樣）。然後$file_count將記錄讀取的文件數量。while循環讀取@ARGV中包含的文件，類似於管道貓。

在第一個for循環中，檢查是否在每個文件中都讀入名稱（if ($names{$name}{count} == $file_count)）。如果是這樣，它計算的百分比之間，如果沒有區別，刪除從%names散列名稱。

最後for循環使用打印自定義排序，by_percent_name結果。

#!/usr/bin/perl 
use strict; 
use warnings; 

my $file_count = @ARGV or die "invoke program as:\nperl $0 *.hgt\n"; 

my %names; 
while (<>) { 
    next if $. == 1; # throw header out 
    my ($name, $perc) = (split ' ')[1,4]; 
    $names{$name}{count}++; 
    my $t = $names{$name}{minmax} ||= [1,0]; 
    $t->[0] = $perc if $perc < $t->[0]; 
    $t->[1] = $perc if $perc > $t->[1]; 
    close ARGV if eof; # reset line counter, '$.', to 1 for next file 
} 

for my $name (keys %names) { 
    if ($names{$name}{count} == $file_count) { 
     $names{$name} = $names{$name}{minmax}[1] - $names{$name}{minmax}[0]; 
    } 
    else { 
     delete $names{$name}; 
    } 
} 

my $i; 
my $total = keys %names; 
for my $name (sort by_percent_name keys %names) { 
    printf "%*d. %s %.6f\n", length($total), ++$i, $name, $names{$name}; 
} 

sub by_percent_name { 
    $names{$b} <=> $names{$a} || $a cmp $b 
}