使用一對Perl正則表達式匹配的無限循環

Question

我用正則表達式寫了一個小Perl腳本來獲取網站的HTML組件。

我知道它不是做這種工作的好方法，但我試圖測試我的正則表達式技巧。

當在while循環中運行兩個正則表達式模式中的任何一個時，它將完美運行並顯示正確的輸出。但是，當我嘗試在while循環中檢查兩個模式時，第二個模式每次匹配並且循環無限運行。

我的腳本：

#!/usr/bin/perl -w 
use strict; 

while (<STDIN>) { 

    while ((m/<span class=\"itempp\">([^<]+)+?<\/span>/g) || 
      (m/<font size=\"-1\">([^<]+)+?<\/font>/g)) { 
     print "$1\n"; 
    } 
} 

我有樣品輸入測試上面的腳本：

<a href="http://linkTest">Link title</a> 
<span class="itempp">$150</span> 
<font size="-1"> (Location)</font> 

所需的輸出：

$150 
(Location) 

謝謝！任何幫助將不勝感激！

Answer 1

每當全局正則表達式匹配失敗時，它將重置下一個全局正則表達式將開始搜索的位置。所以，當你的兩個模式中的第一個模式失敗時，它會迫使第二個模塊再次從字符串的開頭看。

此行爲可以通過添加/c修飾符來禁用，如果正則表達式匹配失敗，修改器將保持該位置不變。

此外，您可以通過刪除轉義字符提高你的模式（"不需要逃逸，/不需要進行轉義，如果你選擇一個不同的分隔符）和捕獲後的多餘+?。

另外use warnings在命令行上比-w好得多。

這是您的代碼的工作版本。

use strict; 
use warnings; 

while (<STDIN>) { 

    while(m|<span class="itempp">([^<]+)</span>|gc 
      or m|<font size="-1">([^<]+)</font>|gc) { 
     print "$1\n"; 
    } 
} 

Answer 2

在匹配後或匹配期間，您沒有更改$_，所以它始終會匹配並運行到無限循環。

要修復它，你可以在print之後加$_=$';，在剩下的字符串中再次運行匹配。

Answer 3

while (<DATA>) { 
    if (m{<(?:span class="itempp"|font size="-1")>\s*([^<]+)}i) { 
     print "$1\n"; 
    } 
} 

__DATA__ 
<a href="http://linkTest">Link title</a> 
<span class="itempp">$150</span> 
<font size="-1"> (Location)</font>