字符串上的模糊匹配

Question

我有一個問題與在MSSQL數據庫中匹配字符串有關。基本上，我有一個包含ICD9和CPT代碼的表格。問題是這些代碼的格式通常是不正確的（即字符太多，缺少小數等等）。我需要能夠從包含正確代碼的查找表中查找每個代碼的描述。

由於這些代碼結構的方式，我可以做一些類型的「漸進式」匹配，至少可以找到代碼的類別。

比方說，正確的代碼是一樣的東西：306.98

而且在這個例子中可以假裝有306和307

之間沒有其他的值，我想剝離十進制和尋找匹配，一次一個字符，直到找不到一個字符。然後選擇最後一個匹配字符串。

因此，306,3069,3098,306981,3069812等將匹配字符串306.98。

我希望對每個人都有意義。我不知道我怎麼會開始這樣做，所以任何建議都會有很大的幫助。

Answer 1

我能弄明白。基本上，我只需要遍歷字符串的每個字符並尋找匹配，直到找不到一個字符。謝謝您的幫助！

/* ICD9 Lookup */ 

USE TSiData_Suite_LWHS_V11 

DECLARE @String NVARCHAR (10) 
DECLARE @Match NVARCHAR(10) 
DECLARE @Substring NVARCHAR (10) 
DECLARE @Description NVARCHAR(MAX) 
DECLARE @Length INT 
DECLARE @Count INT 

SET @String = '309.99999999' 

/* Remove decimal place from string */ 
SET @String = REPLACE(@String,'.','') 

/* Get lenth of string */ 
SET @Length = LEN(@String) 

/* Initialize count */ 
SET @Count = 1 

/* Get Substring */ 
SET @Substring = SUBSTRING(@String,1,@Count) 

/* Start processing */ 
IF (@Length < 1 OR @String IS NULL) 
    /* Validate @String */ 
    BEGIN 

     SET @Description = 'No match found for string. String is not proper length.' 

    END 
ELSE IF ((SELECT COUNT(*) FROM LookupDiseases WHERE REPLACE(LookupCodeDesc,'.','') LIKE @Substring + '%') < 1) 
    /* Check for at least one match */ 
    BEGIN 

     SET @Description = 'No match found for string.' 

    END 
ELSE 
    /* Look for matching code */ 
    BEGIN 

     WHILE ((SELECT COUNT(*) FROM ICD9Lookup WHERE REPLACE(LookupCodeDesc,'.','') LIKE @Substring + '%') <> 1 AND (@Count < @Length + 1)) 
     BEGIN 

      /* Update substring value */ 
      SET @Substring = SUBSTRING(@String,1,@Count + 1) 

      /* Increment @Count */ 
      SET @Count += 1 

      /* Select the first matching code and get description */ 
      SELECT TOP(1) @Match = LookupCodeDesc, @Description = LookupName FROM ICD9Lookup WHERE REPLACE(LookupCodeDesc,'.','') LIKE @Substring + '%' ORDER BY LookupCodeDesc ASC 

     END 
    END 

PRINT @Match 
PRINT @Description 

Answer 2

一種可能的解決方案是將代碼剝離下來到它的基本元件（306），然後執行一個類似操作：

WHERE Code LIKE '306%' 

Answer 3

使用FLOOR函數來剝離小數部分，然後在使用LIKE操作者WHERE子句。

喜歡的東西：

SELECT <COLUMN-LIST> 
    FROM <TABLE-NAME> 
WHERE <THE-COLUMN> LIKE CAST(FLOOR(306.09) AS VARCHAR) + '%' 

Answer 4

這裏，你有你的example.You只需要轉換價值爲nvarchar @string。

DECLARE @string AS NVARCHAR (MAX) = '306.98'; 
DECLARE @Table TABLE (
    TextVal NVARCHAR (MAX)); 

INSERT INTO @Table ([TextVal]) 
SELECT '4444656' 
UNION ALL 
SELECT '30' 
UNION ALL 
SELECT '3069' 
UNION ALL 
SELECT '306989878787' 
; 

WITH numbers 
AS  (SELECT ROW_NUMBER() OVER (ORDER BY (SELECT 1)) AS Number 
     FROM [sys].[objects] AS o1 CROSS JOIN [sys].[objects] AS o2), 
     Chars 
AS  (SELECT SUBSTRING(@string, [Number], 1) AS Let, 
       [Number] 
     FROM [numbers] 
     WHERE [Number] <= LEN(@string)), 
     Joined 
AS  (SELECT [Let], 
       CAST (1 AS BIGINT) AS Number 
     FROM chars 
     WHERE [Number] = 1 
     UNION ALL 
     SELECT [J].[Let] + CASE 
          WHEN [Chars].[Let] = '.' THEN '' ELSE [Chars].[Let] 
          END AS LEt, 
       Chars.[Number] 
     FROM [Joined] AS J 
       INNER JOIN 
       [Chars] 
       ON [Chars].[Number] = [J].[Number] + 1) 
SELECT * 
FROM @Table AS T 
WHERE [T].[TextVal] IN (SELECT [Let] 
         FROM [Joined]) 
      OR [T].[TextVal] LIKE '%'+(SELECT TOP 1 [Let] FROM 
      [Joined] ORDER BY [Number] DESC) +'%'    
         ; 

結果將是：

TextVal 
30 
3069 
306989878787